reserve i, j, n for Nat,
  f for non constant standard special_circular_sequence,
  g for clockwise_oriented non constant standard special_circular_sequence,
  p, q for Point of TOP-REAL 2,
  P for Subset of TOP-REAL 2,
  C for compact non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board;
reserve f for clockwise_oriented non constant standard
  special_circular_sequence;

theorem Th25:
  p in RightComp f implies N-bound L~f > p`2
proof
  set g = Rotate(f,N-min L~f);
A1: L~f = L~g by REVROT_1:33;
  reconsider u = p as Point of Euclid 2 by EUCLID:22;
  assume p in RightComp f;
  then p in RightComp g by REVROT_1:37;
  then u in Int RightComp g by TOPS_1:23;
  then consider r being Real such that
A2: r > 0 and
A3: Ball(u,r) c= RightComp g by GOBOARD6:5;
  reconsider r as Real;
  reconsider k = |[p`1,p`2+r/2]| as Point of Euclid 2 by EUCLID:22;
  dist(u,k) = (Pitag_dist 2).(u,k) by METRIC_1:def 1
    .= sqrt ((p`1 - |[p`1,p`2+r/2]|`1)^2 + (p`2 - |[p`1,p`2+r/2]|`2)^2) by
TOPREAL3:7
    .= sqrt ((p`1 - p`1)^2 + (p`2 - |[p`1,p`2+r/2]|`2)^2)
    .= sqrt ((p`2 - (p`2+r/2))^2)
    .= sqrt ((r/2)^2)
    .= r/2 by A2,SQUARE_1:22;
  then dist(u,k) < r/1 by A2,XREAL_1:76;
  then
A4: k in Ball(u,r) by METRIC_1:11;
  RightComp g misses LeftComp g by Th14;
  then
A5: not |[p`1,p`2+r/2]| in LeftComp g by A3,A4,XBOOLE_0:3;
  set x = |[E-bound L~SpStSeq L~g,p`2+r/2]|;
A6: LSeg(SE-corner L~g,NE-corner L~g) c= L~SpStSeq L~g by TOPREAL6:35;
A7: proj2.x = x`2 by PSCOMP_1:def 6
    .= p`2+r/2;
  N-min L~f in rng f by SPRECT_2:39;
  then
A8: g/.1 = N-min L~g by A1,FINSEQ_6:92;
  then |[p`1,p`2+r/2]|`2 <= N-bound L~g by A5,JORDAN2C:113;
  then p`2+r/2 <= N-bound L~g;
  then
A9: x`2 <= N-bound L~g;
A10: x`1 = E-bound L~g by SPRECT_1:61;
  |[p`1,p`2+r/2]|`2 >= S-bound L~g by A8,A5,JORDAN2C:112;
  then p`2+r/2 >= S-bound L~g;
  then
A11: x`2 >= S-bound L~g;
  LSeg(SE-corner L~g, NE-corner L~g) = { q : q`1 = E-bound L~g & q`2 <=
  N-bound L~g & q`2 >= S-bound L~g } by SPRECT_1:23;
  then x in LSeg(SE-corner L~g,NE-corner L~g) by A9,A11,A10;
  then
  proj2.:L~SpStSeq L~g is bounded_above & p`2+r/2 in proj2.:L~SpStSeq L~g
  by A6,A7,FUNCT_2:35;
  then
A12: upper_bound(proj2.:L~SpStSeq L~g) >= p`2+r/2 by SEQ_4:def 1;
  r/2 > 0 by A2,XREAL_1:139;
  then
A13: p`2+r/2 > p`2+0 by XREAL_1:6;
  N-bound L~SpStSeq L~g = N-bound L~g &
   N-bound L~SpStSeq L~g = upper_bound(proj2
  .:L~ SpStSeq L~g) by SPRECT_1:45,60;
  hence thesis by A1,A12,A13,XXREAL_0:2;
end;
