
theorem Th23:
  for V be non empty VectSp of F_Complex for l be
  linear-Functional of V holds projRe(l) is linear-Functional of RealVS(V)
proof
  let V be non empty VectSp of F_Complex;
  let l be linear-Functional of V;
A1: projRe(l) is homogeneous
  proof
    let x be VECTOR of RealVS(V);
    let r be Real;
    the addLoopStr of V = the addLoopStr of RealVS(V) by Def17;
    then reconsider x1=x as Vector of V;
    r*x = [**r,0**]*x1 by Def17;
    hence (projRe(l)).(r*x) = Re(l.([**r,0**]*x1)) by Def18
      .= Re([**r,0**]*l.x1) by Def8
      .= Re [**r,0**] * Re (l.x1) - Im [**r,0**] * Im (l.x1) by COMPLEX1:9
      .= Re [**r,0**] * Re (l.x1) - 0 * Im (l.x1) by COMPLEX1:12
      .= r * Re (l.x1) by COMPLEX1:12
      .= r*(projRe(l)).x by Def18;
  end;
  projRe(l) is additive
  proof
    let x,y be VECTOR of RealVS(V);
A2: the addLoopStr of V = the addLoopStr of RealVS(V) by Def17;
    then reconsider x1=x, y1=y as Vector of V;
    thus (projRe(l)).(x+y) = Re(l.(x1+y1)) by A2,Def18
      .= Re(l.x1+l.y1) by VECTSP_1:def 20
      .= Re(l.x1)+Re(l.y1) by COMPLEX1:8
      .= Re(l.x1)+(projRe(l)).y by Def18
      .= (projRe(l)).x+(projRe(l)).y by Def18;
  end;
  hence thesis by A1;
end;
