reserve Z for RealNormSpace;
reserve a,b,c,d,e,r for Real;
reserve A,B for non empty closed_interval Subset of REAL;
reserve X,Y for RealBanachSpace;
reserve E for Point of Y;

theorem
  for f be continuous PartFunc of REAL,the carrier of Y
    st ( a<=b & ['a,b'] c= dom f & c in ['a,b'] & d in ['a,b']
     & for x be Real st x in ['min(c,d),max(c,d)']
         holds ||. f/.x .|| <= e )
  holds ||.integral(f,c,d).|| <= e * |.d-c.|
proof
   let f be continuous PartFunc of REAL,the carrier of Y;
   set A = ['min(c,d),max(c,d)'];
   assume that
A1: a<=b & ['a,b'] c= dom f & c in ['a,b'] & d in ['a,b'] and
A2: for x be Real st x in A holds ||. f/.x .|| <= e;
   rng ||.f.|| c= REAL; then
A3: ||.f.|| is Function of dom ||.f.||,REAL by FUNCT_2:2;
B1:A c= ['a,b'] by A1,Lm2;
B2:dom ||.f.|| = dom f by NORMSP_0:def 2; then
   A c= dom ||.f.|| by A1,B1;
   then reconsider g =(||.f.||)| A as Function of A,REAL by A3,FUNCT_2:32;
A4:vol A = |.d-c.| by INTEGRA6:6;
A5: ||.f.|| is_integrable_on A & g|A is bounded
 & ||.integral(f,c,d).|| <= integral(||.f.||,min(c,d),max(c,d)) by A1,Th1922;
   consider h be Function of A,REAL such that
A6: rng h = {e} and
A7: h|A is bounded by INTEGRA4:5;
A8:now let x be Real;
    assume
A9: x in A; then
    g.x = ||.f.||.x by FUNCT_1:49;
    then
A10:g.x = ||. f/.x .|| by A9,B2,A1,B1,NORMSP_0:def 2;
    h.x in {e} by A6,A9,FUNCT_2:4;
    then h.x =e by TARSKI:def 1;
    hence g.x <= h.x by A2,A9,A10;
   end;
   min(c,d) <= c & c <= max(c,d) by XXREAL_0:17,25; then
A12: integral(||.f.||,min(c,d),max(c,d)) = integral(||.f.||,A)
              by INTEGRA5:def 4,XXREAL_0:2;
   h is integrable & integral h = e*vol A by A6,INTEGRA4:4;
   then integral(||.f.||,min(c,d),max(c,d)) <= e * |.d-c.|
      by A12,A7,A8,A5,A4,INTEGRA2:34;
   hence thesis by A5,XXREAL_0:2;
end;
