reserve T,T1,T2,S for non empty TopSpace;
reserve p,q for Point of TOP-REAL 2;

theorem Th25:
  for X being non empty TopSpace, f1,f2 being Function of X,R^1 st
f1 is continuous & f2 is continuous holds ex g being Function of X,R^1 st (for
p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2 holds g.p=r1*r2
  ) & g is continuous
proof
  let X be non empty TopSpace, f1,f2 be Function of X,R^1;
  assume
A1: f1 is continuous & f2 is continuous;
  then consider g1 being Function of X,R^1 such that
A2: for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g1.p=r1+r2 and
A3: g1 is continuous by Th19;
  consider g3 being Function of X,R^1 such that
A4: for p being Point of X,r1 being Real st g1.p=r1 holds g3.p=r1
  *r1 and
A5: g3 is continuous by A3,Th22;
  consider g2 being Function of X,R^1 such that
A6: for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g2.p=r1-r2 and
A7: g2 is continuous by A1,Th21;
  consider g4 being Function of X,R^1 such that
A8: for p being Point of X,r1 being Real st g2.p=r1 holds g4.p=r1
  *r1 and
A9: g4 is continuous by A7,Th22;
  consider g5 being Function of X,R^1 such that
A10: for p being Point of X,r1,r2 being Real st g3.p=r1 & g4.p=r2
  holds g5.p=r1-r2 and
A11: g5 is continuous by A5,A9,Th21;
  consider g6 being Function of X,R^1 such that
A12: for p being Point of X,r1 being Real st g5.p=r1 holds g6.p=(
  1/4) *r1 and
A13: g6 is continuous by A11,Th23;
  for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g6.p=r1*r2
  proof
    let p be Point of X,r1,r2 be Real;
    assume
A14: f1.p=r1 & f2.p=r2;
    then g2.p=r1-r2 by A6;
    then
A15: g4.p=(r1-r2)^2 by A8;
    g1.p=r1+r2 by A2,A14;
    then g3.p=(r1+r2)^2 by A4;
    then g5.p= (r1+r2)^2 -(r1-r2)^2 by A10,A15;
    then g6.p=(1/4)*( r1^2+2*r1*r2+r2^2 -(r1-r2)^2) by A12
      .= r1*r2;
    hence thesis;
  end;
  hence thesis by A13;
end;
