reserve x for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th25:
  for Kb being Subset of TOP-REAL 2 st Kb={q: -1=q`1 & -1<=q`2 & q
`2<=1 or q`1=1 & -1<=q`2 & q`2<=1 or -1=q`2 & -1<=q`1 & q`1<=1 or 1=q`2 & -1<=q
  `1 & q`1<=1} holds Kb is being_simple_closed_curve & Kb is compact
proof
  set v= |[1,0]|;
  let Kb be Subset of TOP-REAL 2;
  assume
A1: Kb={q: -1=q`1 & -1<=q`2 & q`2<=1 or q`1=1 & -1<=q`2 & q`2<=1 or -1=q
  `2 & -1<=q`1 & q`1<=1 or 1=q`2 & -1<=q`1 & q`1<=1};
  v`1=1 & v`2=0 by EUCLID:52;
  then
  |[1,0]| in {q: -1=q`1 & -1<=q`2 & q`2<=1 or q`1=1 & -1<=q`2 & q`2<=1 or
  -1=q`2 & -1<=q`1 & q`1<=1 or 1=q`2 & -1<=q`1 & q`1<=1};
  then reconsider Kbd=Kb as non empty Subset of TOP-REAL 2 by A1;
  set P=Kb;
  id ((TOP-REAL 2)|Kbd) is being_homeomorphism;
  hence Kb is being_simple_closed_curve by A1,Th24;
  then consider
  f being Function of (TOP-REAL 2)|R^2-unit_square, (TOP-REAL 2)|P
  such that
A2: f is being_homeomorphism by TOPREAL2:def 1;
  per cases;
  suppose
A3: P is empty;
    Kbd <>{};
    hence thesis by A3;
  end;
  suppose
    P is non empty;
    then reconsider R = P as non empty Subset of TOP-REAL 2;
    f is continuous & rng f = [#]((TOP-REAL 2)|P) by A2,TOPS_2:def 5;
    then (TOP-REAL 2)|R is compact by COMPTS_1:14;
    hence thesis by COMPTS_1:3;
  end;
end;
