reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem Th25:
  for P being Subset of R^1,a being Real st P = { s: a<s }
  holds P is open
proof
  let P be Subset of R^1,a be Real;
  assume
A1: P = { s: a<s };
  for c being Point of RealSpace st c in P ex r being Real st r > 0
  & Ball(c,r) c= P
  proof
    let c be Point of RealSpace;
    reconsider n = c as Element of REAL by METRIC_1:def 13;
    reconsider r = n-a as Real;
    assume c in P;
    then
A2: ex s st s=n & a<s by A1;
    take r;
    now
      let x be object;
      assume
A3:   x in Ball(c,r);
      then reconsider t = x as Element of REAL by METRIC_1:def 13;
      reconsider u = x as Point of RealSpace by A3;
      Ball(c,r) = {q where q is Element of RealSpace :dist(c,q)<r} by
METRIC_1:17;
      then ex v being Element of RealSpace st v = u & dist(c,v)<r by A3;
      then (real_dist).(n,t) < r by METRIC_1:def 1,def 13;
      then
A4:   |. n - t .| < r by METRIC_1:def 12;
      n - t <= |. n - t .| by ABSVALUE:4;
      then n - t < n - a by A4,XXREAL_0:2;
      then a<t by XREAL_1:10;
      hence x in P by A1;
    end;
    hence thesis by A2,XREAL_1:50;
  end;
  hence thesis by TOPMETR:15,def 6;
end;
