
theorem Th25:
  for f being FinSequence of TOP-REAL 2, q being Point of TOP-REAL
  2, i being Nat st f is being_S-Seq & 1 <= i & i+1 <= len f & q in
  LSeg(f,i) holds LE f/.i, q, L~f, f/.1, f/.len f
proof
  let f be FinSequence of TOP-REAL 2, q be Point of TOP-REAL 2, i be Nat;
  assume that
A1: f is being_S-Seq and
A2: 1<=i & i+1<=len f and
A3: q in LSeg(f,i);
  set p1 = f/.1, p2 = f/.len f, q1 = f/.i;
A4: 2 <= len f by A1,TOPREAL1:def 8;
  then reconsider P = L~f as non empty Subset of TOP-REAL 2 by TOPREAL1:23;
  i in dom f by A2,SEQ_4:134;
  then
A5: q1 in P by A4,GOBOARD1:1;
A6: for g being Function of I[01], (TOP-REAL 2)|P,
   s1,s2 be Real st g is
being_homeomorphism & g.0=p1 & g.1=p2 & g.s1=q1 & 0<=s1 & s1<=1 & g.s2=q & 0<=
  s2 & s2<=1 holds s1<=s2
  proof
    let g be Function of I[01], (TOP-REAL 2)|P, s1,s2 be Real;
    assume that
A7: g is being_homeomorphism and
A8: g.0=p1 & g.1=p2 and
A9: g.s1=q1 and
A10: 0<=s1 & s1<=1 and
A11: g.s2=q and
A12: 0<=s2 & s2<=1;
A13: dom g = [#]I[01] by A7,TOPS_2:def 5
      .= the carrier of I[01];
    then
A14: s1 in dom g by A10,BORSUK_1:43;
    consider r1, r2 be Real such that
    r1 < r2 and
A15: 0 <= r1 & r1 <= 1 and
    0 <= r2 and
    r2 <= 1 and
A16: LSeg (f, i) = g.: [.r1, r2.] and
A17: g.r1 = q1 and
    g.r2 = f/.(i+1) by A1,A2,A7,A8,JORDAN5B:7;
    consider r39 be object such that
A18: r39 in dom g and
A19: r39 in [.r1, r2.] and
A20: g.r39 = q by A3,A16,FUNCT_1:def 6;
    r39 in { l where l is Real: r1 <= l & l <= r2 }
     by A19,RCOMP_1:def 1;
    then consider r3 be Real such that
A21: r3 = r39 and
A22: r1 <= r3 and
    r3 <= r2;
A23: g is one-to-one by A7,TOPS_2:def 5;
A24: r1 in dom g by A15,A13,BORSUK_1:43;
    s2 in dom g by A12,A13,BORSUK_1:43;
    then s2 = r3 by A11,A18,A20,A21,A23,FUNCT_1:def 4;
    hence thesis by A9,A17,A22,A24,A14,A23,FUNCT_1:def 4;
  end;
  q in P by A3,SPPOL_2:17;
  hence thesis by A5,A6;
end;
