
theorem Th25:
  for X be RealNormSpace for s be sequence of X
   for n,m be Nat st n<=m
  holds ||.Partial_Sums(s).m - Partial_Sums(s).n.|| <= |.
  Partial_Sums(||.s.||).m - Partial_Sums(||.s.||).n.|
proof
  let X be RealNormSpace;
  let s be sequence of X;
  set s1=Partial_Sums(s);
  set s2=Partial_Sums(||.s.||);
  let n,m be Nat;
  assume n<=m;
  then reconsider k=m-n as Element of NAT by INT_1:5;
  defpred X[Nat] means
||.s1.(n+$1) - s1.n.|| <= |.s2.(n+$1) - s2
  .n.|;
A1: n+k = m;
  now
    let k be Nat;
    ||.s.k.|| >=0;
    hence ||.s.||.k >= 0 by NORMSP_0:def 4;
  end;
  then
A2: s2 is non-decreasing by SERIES_1:16;
A3: for k be Nat st X[k] holds X[k+1]
  proof
    let k be Nat;
A4: |.s2.(n+(k+1)) - s2.n.| = |.s2.(n+k) + ( ||.s.||).(n+k+1) - s2.n.|
    by SERIES_1:def 1
      .= |.s2.(n+k) + ||.s.(n+k+1).||-s2.n.| by NORMSP_0:def 4
      .= |.||.s.(n+k+1).|| + (s2.(n+k) - s2.n).|;
    ||. s1.(n+(k+1)) - s1.n.|| = ||. s.(n+k+1) + s1.(n+k) - s1.n .|| by
BHSP_4:def 1
      .= ||. s.(n+k+1) + (s1.(n+k) - s1.n).|| by RLVECT_1:def 3;
    then
A5: ||. s1.(n+(k+1))-s1.n .|| <= ||.s.(n+k+1).||+||.s1.(n+k) - s1.n.|| by
NORMSP_1:def 1;
    s2.(n+k)>=s2.n by A2,SEQM_3:5;
    then
A6: s2.(n+k) - s2.n >= 0 by XREAL_1:48;
    assume ||. s1.(n+k) - s1.n.|| <= |.s2.(n+k) - s2.n.|;
    then
    ||.s.(n+k+1).|| + ||. s1.(n+k) - s1.n.|| <= ||.s.(n+k+1).|| + |.s2.
    (n+k) - s2.n.| by XREAL_1:7;
    then ||. s1.(n+(k+1))-s1.n.|| <= ||. s.(n+k+1).||+ |.s2.(n+k)-s2.n.| by A5
,XXREAL_0:2;
    then
 ||. s1.(n+(k+1))-s1.n .|| <= ||. s.(n+k+1).||+(s2.(n+k)-s2.n) by A6,
ABSVALUE:def 1;
    hence thesis by A4,ABSVALUE:def 1;
  end;
  ||.s1.(n+0) - s1.n.|| = ||.0.X.|| by RLVECT_1:15
    .= 0;
  then
A7: X[0] by COMPLEX1:46;
  for k be Nat holds X[k] from NAT_1:sch 2(A7,A3);
  hence thesis by A1;
end;
