reserve A,B,p,q,r,s for Element of LTLB_WFF,
  n for Element of NAT,
  X for Subset of LTLB_WFF,
  g for Function of LTLB_WFF,BOOLEAN,
  x,y for set;

theorem Th25: tau1.p c= Sub.p
  proof
    defpred P1[Element of l] means tau1.$1 c= Sub.$1;
    set f = TFALSUM;
A1: for n holds P1[ prop n]
    proof
      let n;
      set pr = prop n;
      tau1.pr = {pr} by Def4
      .= Sub.pr by Def6;
      hence thesis;
    end;
A2: for r, s st P1[r] & P1[s] holds P1[r 'U' s] & P1[r => s]
    proof
      let r,s;
      assume that
A3:   P1[r]and
A4:   P1[s];
      thus P1[r 'U' s]
      proof
        set f = r 'U' s;
        {f} c= Sub.f by Th24,ZFMISC_1:31;
        hence thesis by Def4;
      end;
      thus P1[r => s]
      proof
        set f = r => s;
A5:     Sub.f = {f} \/ Sub.r \/ Sub.s by Def6;
        {f} \/ tau1.r c= {f} \/ Sub.r & tau1.f = {f} \/ tau1.r \/ tau1.s
        by XBOOLE_1: 13,A3, Def4;
        hence thesis by A5,A4,XBOOLE_1:13;
      end;
    end;
    tau1.f = {f} by Def4
    .= Sub.f by Def6;
    then A6: P1[f];
    for p holds P1[p] from HILBERT2:sch 2(A6,A1,A2);
    hence thesis;
  end;
