reserve X for non empty set;
reserve e for set;
reserve x for Element of X;
reserve f,g for PartFunc of X,ExtREAL;
reserve S for SigmaField of X;
reserve F for Function of RAT,S;
reserve p,q for Rational;
reserve r for Real;
reserve n,m for Nat;
reserve A,B for Element of S;

theorem
  f is A-measurable implies max+(f) is A-measurable
proof
  assume
A1: f is A-measurable;
 for r be Real holds A /\ less_dom(max+(f), r) in S
  proof
    let r be Real;
    reconsider r as Real;
 now per cases;
      suppose
A2:     0 < r;
     for x being object st x in less_dom(max+(f), r) holds
        x in less_dom(f, r)
        proof
          let x be object;
          assume
A3:       x in less_dom(max+(f), r);
then A4:       x in dom max+(f) by MESFUNC1:def 11;
A5:       max+(f).x <  r by A3,MESFUNC1:def 11;
          reconsider x as Element of X by A3;
A6:       max(f.x,0.) <  r by A4,A5,Def2;
then A7:      f.x <=  r by XXREAL_0:30;
      f.x <>  r
          proof
            assume
A8:        f.x =  r;
then         max(f.x,0.) = 0. by A6,XXREAL_0:16;
            hence contradiction by A6,A8,XXREAL_0:def 10;
          end;
then A9:      f.x <  r by A7,XXREAL_0:1;
      x in dom f by A4,Def2;
          hence thesis by A9,MESFUNC1:def 11;
        end;
then A10:    less_dom(max+(f), r) c= less_dom(f, r);
    for x being object st x in less_dom(f, r) holds
        x in less_dom(max+(f), r)
        proof
          let x be object;
          assume
A11:      x in less_dom(f, r);
then A12:      x in dom f by MESFUNC1:def 11;
A13:      f.x <  r by A11,MESFUNC1:def 11;
          reconsider x as Element of X by A11;
A14:      x in dom (max+(f)) by A12,Def2;
      now per cases;
            suppose
          0. <= f.x;
then           max(f.x,0.) = f.x by XXREAL_0:def 10;
then           max+(f).x = f.x by A14,Def2;
              hence thesis by A13,A14,MESFUNC1:def 11;
            end;
            suppose
          not 0. <= f.x;
then           max(f.x,0.) = 0. by XXREAL_0:def 10;
then           max+(f).x = 0. by A14,Def2;
              hence thesis by A2,A14,MESFUNC1:def 11;
            end;
          end;
          hence thesis;
        end;
then
    less_dom(f, r) c= less_dom(max+(f), r);
then     less_dom
(max+(f), r) = less_dom(f, r) by A10;
        hence thesis by A1;
      end;
      suppose
A15:    r <= 0;
    for x being Element of X holds not x in less_dom(max+(f), r)
        proof
          let x be Element of X;
          assume
A16:      x in less_dom(max+(f), r);
then A17:      x in dom(max+(f)) by MESFUNC1:def 11;
A18:      max+(f).x <  r by A16,MESFUNC1:def 11;
      max+(f).x = max(f.x,0.) by A17,Def2;
          hence contradiction by A15,A18,XXREAL_0:25;
        end;
then     less_dom(max+(f), r) = {} by SUBSET_1:4;
        hence thesis by PROB_1:4;
      end;
    end;
    hence thesis;
  end;
  hence thesis;
end;
