reserve k,m,n for Nat,
  i1,i2,i3 for Integer,
  e for set;
reserve i,k,m,n,p,x,y for Nat;
reserve a for Tuple of n,(k-SD);

theorem Th24:
  k >= 2 & m is_represented_by 1,k & n is_represented_by 1,k
  implies SDDec(DecSD(m,1,k)'+'DecSD(n,1,k)) = SD_Add_Data(m+n,k)
proof
  assume that
A1: k >= 2 and
A2: m is_represented_by 1,k and
A3: n is_represented_by 1,k;
  set N = DecSD(n,1,k);
  set M = DecSD(m,1,k);
A4: 1 in Seg 1 by FINSEQ_1:1;
  then
A5: DigA((M '+' N),1) = Add(M,N,1,k) by Def14
    .= SD_Add_Data(DigA(M,1)+DigA(N,1),k) + SD_Add_Carry(DigA(M,1 -'1)+DigA(
  N,1 -'1)) by A1,A4,Def13
    .= SD_Add_Data(DigA(M,1)+DigA(N,1),k) + SD_Add_Carry(DigA(M,0)+DigA(N,1
  -'1)) by XREAL_1:232
    .= SD_Add_Data(DigA(M,1)+DigA(N,1),k) + SD_Add_Carry(DigA(M,0)+DigA(N,0)
  ) by XREAL_1:232
    .= SD_Add_Data(DigA(M,1)+DigA(N,1),k) + SD_Add_Carry(0+DigA(N,0)) by Def3
    .= SD_Add_Data(DigA(M,1)+DigA(N,1),k) + 0 by Def3,Th17
    .= SD_Add_Data(m+DigA(N,1),k) by A2,Th20
    .= SD_Add_Data(m+n,k) by A3,Th20;
A6: (DigitSD(M '+' N))/.1 = SubDigit((M '+' N),1,k) by A4,Def6
    .= (Radix(k) |^ 0)*DigA((M '+' N),1) by XREAL_1:232
    .= 1*DigA((M '+' N),1) by NEWTON:4
    .= SD_Add_Data(m+n,k) by A5;
  reconsider w = SD_Add_Data(m+n,k) as Element of INT by INT_1:def 2;
A7: len (DigitSD(M '+' N)) = 1 by CARD_1:def 7;
  1 in Seg 1 by FINSEQ_1:1;
  then 1 in dom DigitSD(M '+' N) by A7,FINSEQ_1:def 3;
  then DigitSD(M '+' N).1 = SD_Add_Data(m+n,k) by A6,PARTFUN1:def 6;
  then SDDec(M '+' N) = Sum <*w*> by A7,FINSEQ_1:40
    .= SD_Add_Data(m+n,k) by RVSUM_1:73;
  hence thesis;
end;
