reserve x,X,Y for set;
reserve g,r,r1,r2,p,p1,p2 for Real;
reserve R for Subset of REAL;
reserve seq,seq1,seq2,seq3 for Real_Sequence;
reserve Ns for increasing sequence of NAT;
reserve n for Nat;
reserve W for non empty set;
reserve h,h1,h2 for PartFunc of W,REAL;
reserve e1,e2 for ExtReal;
reserve h,h1,h2 for PartFunc of REAL,REAL;

theorem Th25:
  h|Y is non-increasing iff for r1,r2 st r1 in Y /\ dom h & r2 in
  Y /\ dom h & r1<=r2 holds h.r2 <= h.r1
proof
  thus h|Y is non-increasing implies for r1,r2 st r1 in Y /\ dom h & r2 in Y
  /\ dom h & r1<=r2 holds h.r2 <= h.r1
  proof
    assume
A1: h|Y is non-increasing;
    let r1,r2 such that
A2: r1 in Y /\ dom h & r2 in Y /\ dom h and
A3: r1<=r2;
    now
      per cases by A3,XXREAL_0:1;
      suppose
        r1 < r2;
        hence thesis by A1,A2,Th23;
      end;
      suppose
        r1 = r2;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  assume
A4: for r1,r2 st r1 in Y /\ dom h & r2 in Y /\ dom h & r1<=r2 holds h.
  r2<=h.r1;
  let r1,r2;
  assume that
A5: r1 in dom(h|Y) & r2 in dom(h|Y) and
A6: r1<r2;
A7: (h|Y).r1 = h.r1 & (h|Y).r2 = h.r2 by A5,FUNCT_1:47;
  r1 in Y /\ dom h & r2 in Y /\ dom h by A5,RELAT_1:61;
  hence thesis by A4,A6,A7;
end;
