reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem Th25:
  for p be Real st (r*L1+(1-r)*L2).v <= p & p <= (s*L1+(1-s)*L2).v
     ex rs be Real st (rs*L1+(1-rs)*L2).v = p &
                      (r <= s implies r <= rs & rs <= s) &
                      (s <= r implies s <= rs & rs <= r)
  proof
    let p be Real;
    set rv=(r*L1+(1-r)*L2).v,sv=(s*L1+(1-s)*L2).v;
    set v1=L1.v,v2=L2.v;
    A1: rv=(r*L1).v+((1-r)*L2).v by RLVECT_2:def 10
    .=r*v1+((1-r)*L2).v by RLVECT_2:def 11
    .=r*v1+(1-r)*v2 by RLVECT_2:def 11;
    A2: sv=(s*L1).v+((1-s)*L2).v by RLVECT_2:def 10
    .=s*v1+((1-s)*L2).v by RLVECT_2:def 11
    .=s*v1+(1-s)*v2 by RLVECT_2:def 11;
    assume that
    A3: rv<=p and
    A4: p<=sv;
      per cases;
      suppose A5: rv=sv;
        take r;
        thus thesis by A3,A4,A5,XXREAL_0:1;
      end;
      suppose rv<>sv;
        then A6: sv-rv<>0;
        set y=(p-rv)/(sv-rv);
        set x=(sv-p)/(sv-rv);
        take rs=r*x+s*y;
        A7: r*x+r*y=r*(x+y) & s*x+s*y=s*(x+y);
        A8: x+y=((sv-p)+(p-rv))/(sv-rv) by XCMPLX_1:62
        .=1 by A6,XCMPLX_1:60;
        A9: p-rv>=rv-rv by A3,XREAL_1:9;
        thus p=p*(sv-rv)/(sv-rv) by A6,XCMPLX_1:89
        .=(rv*(sv-p)+sv*(p-rv))/(sv-rv)
        .=(rv*(sv-p))/(sv-rv)+(sv*(p-rv))/(sv-rv) by XCMPLX_1:62
        .=(rv*(sv-p))/(sv-rv)+(p-rv)/(sv-rv)*sv by XCMPLX_1:74
        .=x*(r*v1+(1-r)*v2)+y*(s*v1+(1-s)*v2) by A1,A2,XCMPLX_1:74
        .=rs*v1+(x+y)*v2-rs*v2
        .=rs*v1+1*v2-rs*v2 by A8
        .=rs*v1+(1-rs)*v2
        .=rs*v1+((1-rs)*L2).v by RLVECT_2:def 11
        .=(rs*L1).v+((1-rs)*L2).v by RLVECT_2:def 11
        .=(rs*L1+(1-rs)*L2).v by RLVECT_2:def 10;
        A10: sv-rv>=sv-p & sv-p>=p-p by A3,A4,XREAL_1:9,10;
        hereby assume r<=s;
          then r*x<=s*x & r*y<=s*y by A9,A10,XREAL_1:64;
          hence r<=rs & rs<=s by A7,A8,XREAL_1:6;
        end;
        assume A11: s<=r;
        then A12: r*x>=s*x by A10,XREAL_1:64;
        sv-rv>=p-rv by A4,XREAL_1:9;
        then r*y>=s*y by A9,A11,XREAL_1:64;
        hence thesis by A7,A8,A12,XREAL_1:6;
    end;
  end;
