reserve X,Y,Z,Z1,Z2,D for set,x,y for object;
reserve SFX,SFY,SFZ for set;

theorem
  X /\ union SFY = union INTERSECTION({X},SFY)
proof
A1: union INTERSECTION({X},SFY) c= X /\ union SFY
  proof
    let x be object;
    assume x in union INTERSECTION({X},SFY);
    then consider Z such that
A2: x in Z and
A3: Z in INTERSECTION({X},SFY) by TARSKI:def 4;
    consider X1,X2 be set such that
A4: X1 in {X} and
A5: X2 in SFY and
A6: Z = X1 /\ X2 by A3,Def5;
    x in X2 by A2,A6,XBOOLE_0:def 4;
    then
A7: x in union SFY by A5,TARSKI:def 4;
    X1 = X by A4,TARSKI:def 1;
    then x in X by A2,A6,XBOOLE_0:def 4;
    hence thesis by A7,XBOOLE_0:def 4;
  end;
  X /\ union SFY c= union INTERSECTION({X},SFY)
  proof
    let x be object;
    assume
A8: x in X /\ union SFY;
    then x in union SFY by XBOOLE_0:def 4;
    then consider Y such that
A9: x in Y and
A10: Y in SFY by TARSKI:def 4;
    x in X by A8,XBOOLE_0:def 4;
    then
A11: x in X /\ Y by A9,XBOOLE_0:def 4;
    X in {X} by TARSKI:def 1;
    then X /\ Y in INTERSECTION({X},SFY) by A10,Def5;
    hence thesis by A11,TARSKI:def 4;
  end;
  hence thesis by A1;
end;
