reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem
  for P, Q being Subset of T holds P is bounded & Q is bounded & P meets
  Q implies diameter (P \/ Q) <= diameter P + diameter Q
proof
  let P, Q be Subset of T;
  assume that
A1: P is bounded and
A2: Q is bounded and
A3: P /\ Q <> {};
  set g = the Element of P /\ Q;
A4: g in Q by A3,XBOOLE_0:def 4;
  set s = diameter P + diameter Q;
  set b = diameter Q;
A5: b<=s by A1,Th21,XREAL_1:31;
  set a = diameter P;
A6: g in P by A3,XBOOLE_0:def 4;
  reconsider g as Element of T by A3,TARSKI:def 3;
A7: a<=s by A2,Th21,XREAL_1:31;
A8: for x,y being Point of T st x in P \/ Q & y in P \/ Q holds dist(x,y)<= s
  proof
    let x,y be Point of T such that
A9: x in P \/ Q and
A10: y in P \/ Q;
A11: dist(x,y)<=dist(x,g)+dist(g,y) by METRIC_1:4;
    now
      per cases by A9,XBOOLE_0:def 3;
      suppose
A12:    x in P;
        now
          per cases by A10,XBOOLE_0:def 3;
          suppose
            y in P;
            then dist(x,y)<=a by A1,A12,Def8;
            hence thesis by A7,XXREAL_0:2;
          end;
          suppose
A13:        y in Q;
A14:        dist(x,g)<=a by A1,A6,A12,Def8;
            dist(g,y)<=b by A2,A4,A13,Def8;
            then dist(x,g)+dist(g,y)<=a+b by A14,XREAL_1:7;
            hence thesis by A11,XXREAL_0:2;
          end;
        end;
        hence thesis;
      end;
      suppose
A15:    x in Q;
        now
          per cases by A10,XBOOLE_0:def 3;
          suppose
A16:        y in P;
A17:        dist(x,g)<=b by A2,A4,A15,Def8;
            dist(g,y)<=a by A1,A6,A16,Def8;
            then dist(x,g)+dist(g,y)<=b+a by A17,XREAL_1:7;
            hence thesis by A11,XXREAL_0:2;
          end;
          suppose
            y in Q;
            then dist(x,y)<=b by A2,A15,Def8;
            hence thesis by A5,XXREAL_0:2;
          end;
        end;
        hence thesis;
      end;
    end;
    hence thesis;
  end;
  P <> {} & P \/ Q is bounded by A1,A2,A3,Th13;
  hence thesis by A8,Def8;
end;
