reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem Th25:
  for T being set, F, G being Subset-Family of T holds card
  INTERSECTION (F,G) c= card [:F,G:]
proof
  deffunc F(set) = $1`1 /\ $1`2;
  let T be set, F, G be Subset-Family of T;
  set XX = [:F,G:];
  set IN = { F(X) where X is Element of [:bool T, bool T:] : X in XX };
  set A = [:bool T, bool T:];
  set AL = F, BL = G;
  set C = INTERSECTION(AL,BL);
A1: IN c= C
  proof
    let a be object;
    assume a in IN;
    then consider X being Element of [:bool T, bool T:] such that
A2: a = F(X) and
A3: X in XX;
    X`1 in F & X`2 in G by A3,MCART_1:10;
    hence thesis by A2,SETFAM_1:def 5;
  end;
A4: C c= IN
  proof
    let a be object;
    assume a in C;
    then consider X,Y be set such that
A5: X in AL & Y in BL and
A6: a = X /\ Y by SETFAM_1:def 5;
    reconsider X,Y as Subset of T by A5;
    set XY = [X,Y];
A7: XY`1 = X & XY`2 = Y;
    XY in XX by A5,ZFMISC_1:87;
    hence thesis by A6,A7;
  end;
  card { F(w) where w is Element of A : w in XX } c= card XX from TREES_2:
  sch 2;
  hence thesis by A1,A4,XBOOLE_0:def 10;
end;
