reserve p,p1,p2,p3,p11,p22,q,q1,q2 for Point of TOP-REAL 2,
  f,h for FinSequence of TOP-REAL 2,
  r,r1,r2,s,s1,s2 for Real,
  u,u1,u2,u5 for Point of Euclid 2,
  n,m,i,j,k for Nat,
  N for Nat,
  x,y,z for set;
reserve lambda for Real;

theorem
  |[r1,r2]| in Ball(u,r) & |[s1,s2]| in Ball(u,r) implies |[r1,s2]| in
  Ball(u,r) or |[s1,r2]| in Ball(u,r)
proof
  assume that
A1: |[r1,r2]| in Ball(u,r) and
A2: |[s1,s2]| in Ball(u,r);
A3: r > 0 by A1,TBSP_1:12;
  per cases;
  suppose
    |[r1,s2]| in Ball(u,r);
    hence thesis;
  end;
  suppose
A4: not |[r1,s2]| in Ball(u,r);
    reconsider p = u as Point of TOP-REAL 2 by EUCLID:22;
    set p1 = |[r1,s2]|, p2 = |[s1,r2]|, p3 = |[s1,s2]|, p4 = |[r1,r2]|;
    reconsider u1 = p1, u2 = p2, u3 = p3, u4 = p4 as Point of Euclid 2 by
EUCLID:22;
    set a = (p`1 - p1`1)^2 + (p`2 - p1`2)^2, b = (p`1 - p4`1)^2 + (p`2 - p4`2)
^2, c = (p`1 - p3`1)^2 + (p`2 - p3`2)^2, d = (p`1 - p2`1)^2 + (p`2 - p2`2)^2;
    (Pitag_dist 2).(u,u1) = dist(u,u1) & r <= dist(u,u1) by A4,METRIC_1:11
,def 1;
    then r <= sqrt a by Th7;
    then
A5: r * r <= (sqrt a)^2 by A3,XREAL_1:66;
    (p`1 - p1`1)^2 >= 0 & (p`2 - p1`2)^2 >= 0 by XREAL_1:63;
    then
A6: r^2 <= a by A5,SQUARE_1:def 2;
    (Pitag_dist 2).(u,u3) = dist(u,u3) & dist(u,u3) < r by A2,METRIC_1:11,def 1
;
    then
A10: sqrt c < r by Th7;
A11: (p`1 - p3`1)^2 >= 0 & (p`2 - p3`2)^2 >= 0 by XREAL_1:63;
    then 0<=sqrt c by SQUARE_1:def 2;
    then (sqrt c)^2 < r*r by A10,XREAL_1:96;
    then
A12: c < r*r by A11,SQUARE_1:def 2;
    (Pitag_dist 2).(u,u4) = dist(u,u4) & dist(u,u4) < r by A1,METRIC_1:11,def 1
;
    then
A13: sqrt b < r by Th7;
    c + b = a + d;
    then
A14: r^2+d <= c + b by A6,XREAL_1:6;
A15: (p`1 - p4`1)^2 >= 0 & (p`2 - p4`2)^2 >= 0 by XREAL_1:63;
    then 0<=sqrt b by SQUARE_1:def 2;
    then (sqrt b)^2 < r*r by A13,XREAL_1:96;
    then b < r^2 by A15,SQUARE_1:def 2;
    then c+b <r^2 + r^2 by A12,XREAL_1:8;
    then r^2+d < r^2+r^2 by A14,XXREAL_0:2;
    then
A16: d < r^2+r^2 - r^2 by XREAL_1:20;
    (p`1 - p2`1)^2 >= 0 & (p`2 - p2`2)^2 >= 0 by XREAL_1:63;
    then sqrt d < sqrt(r^2) by A16,SQUARE_1:27;
    then
A17: sqrt d < r by A3,SQUARE_1:22;
    dist(u,u2) = (Pitag_dist 2).(u,u2) by METRIC_1:def 1
      .= sqrt d by Th7;
    hence thesis by A17,METRIC_1:11;
  end;
end;
