reserve P,P1,P2,R for Subset of TOP-REAL 2,
  p,p1,p2,p3,p11,p22,q,q1,q2,q3,q4 for Point of TOP-REAL 2,
  f,h for FinSequence of TOP-REAL 2,
  r for Real,
  u for Point of Euclid 2,
  n,m,i,j,k for Nat,
  x,y for set;
reserve P, R for Subset of TOP-REAL 2;

theorem Th25:
  R is being_Region & p in R & P = {q: q=p or ex P1 being Subset
  of TOP-REAL 2 st P1 is_S-P_arc_joining p,q & P1 c=R} implies P is open
proof
  assume that
A1: R is being_Region and
A2: p in R and
A3: P = {q: q=p or ex P1 being Subset of TOP-REAL 2 st P1
  is_S-P_arc_joining p,q & P1 c=R};
  reconsider RR = R, PP=P as Subset of the TopStruct of TOP-REAL 2;
  R is open by A1;
  then
A4: RR is open by PRE_TOPC:30;
  now
    let u;
    reconsider p2=u as Point of TOP-REAL 2 by TOPREAL3:8;
    assume u in P;
    then consider q1 such that
A5: q1=u and
A6: q1=p or ex P1 being Subset of TOP-REAL 2 st P1 is_S-P_arc_joining
    p,q1 & P1 c=R by A3;
    now
      per cases by A6;
      suppose
        q1=p;
        hence p2 in R by A2,A5;
      end;
      suppose
        ex P1 being Subset of TOP-REAL 2 st P1 is_S-P_arc_joining p,
        q1 & P1 c=R;
        then consider P2 being Subset of TOP-REAL 2 such that
A7:     P2 is_S-P_arc_joining p,q1 and
A8:     P2 c=R;
        p2 in P2 by A5,A7,Th3;
        hence p2 in R by A8;
      end;
    end;
    then consider r being Real such that
A9: r>0 and
A10: Ball(u,r) c= RR by A4,Lm1,TOPMETR:15;
    take r;
    thus r>0 by A9;
    reconsider r9= r as Real;
A11: p2 in Ball(u,r9) by A9,TBSP_1:11;
    thus Ball(u,r) c= P
    proof
      let x be object;
      assume
A12:  x in Ball(u,r);
      then reconsider q=x as Point of TOP-REAL 2 by A10,TARSKI:def 3;
      now
        per cases;
        suppose
          q=p;
          hence thesis by A3;
        end;
        suppose
A13:      q<>p;
A14:      now
            assume q1=p;
            then p in Ball(u,r9) by A5,A9,TBSP_1:11;
            then consider P2 being Subset of TOP-REAL 2 such that
A15:        P2 is_S-P_arc_joining p,q and
A16:        P2 c= Ball(u,r9) by A12,A13,Th10;
            reconsider P2 as Subset of TOP-REAL 2;
            P2 c= R by A10,A16;
            hence thesis by A3,A15;
          end;
          now
            assume q1<>p;
            then
            ex P1 being Subset of TOP-REAL 2 st P1 is_S-P_arc_joining p,q
            & P1 c=R by A5,A6,A10,A11,A12,A13,Th23;
            hence thesis by A3;
          end;
          hence thesis by A14;
        end;
      end;
      hence thesis;
    end;
  end;
  then PP is open by Lm1,TOPMETR:15;
  hence thesis by PRE_TOPC:30;
end;
