reserve n for Nat,
  a, b, r, w for Real,
  x, y, z for Point of TOP-REAL n,
  e for Point of Euclid n;

theorem
  for f being homogeneous additive Function of TOP-REAL n, TOP-REAL n, X
  being convex Subset of TOP-REAL n holds f.:X is convex
proof
  let f be homogeneous additive Function of TOP-REAL n, TOP-REAL n, X be
  convex Subset of TOP-REAL n;
  let p, q be Point of TOP-REAL n;
  assume p in f.:X;
  then consider p0 being Point of TOP-REAL n such that
A1: p0 in X and
A2: p = f.p0 by FUNCT_2:65;
  assume q in f.:X;
  then consider q0 being Point of TOP-REAL n such that
A3: q0 in X and
A4: q = f.q0 by FUNCT_2:65;
A5: LSeg(p0,q0) c= X by A1,A3,JORDAN1:def 1;
  let x be object;
  assume x in LSeg(p,q);
  then consider l being Real such that
A6: x = (1-l)*p + l*q and
A7: 0 <= l & l <= 1;
  set a = (1-l)*p0 + l*q0;
A8: a in LSeg(p0,q0) by A7;
  f.a = f.((1-l)*p0) + f.(l*q0) by VECTSP_1:def 20
    .= f.((1-l)*p0) + l*f.q0 by Def4
    .= x by A2,A4,A6,Def4;
  hence thesis by A8,A5,FUNCT_2:35;
end;
