reserve A,B,C for Ordinal,
  K,L,M,N for Cardinal,
  x,y,y1,y2,z,u for object,X,Y,Z,Z1,Z2 for set,
  n for Nat,
  f,f1,g,h for Function,
  Q,R for Relation;
reserve ff for Cardinal-Function;

theorem Th26:
  product f = {} iff {} in rng f
proof
  thus product f = {} implies {} in rng f
  proof
    assume that
A1: product f = {} and
A2: not {} in rng f;
A3: now
      assume dom f = {};
      then for x being object st x in dom f holds f.x in f.x;
      hence thesis by A1,Def5;
    end;
    now
      assume dom f <> {};
      then reconsider M = rng f as non empty set by RELAT_1:42;
      X in M implies X <> {} by A2;
      then consider f1 such that
      dom f1 = M and
A4:   for X st X in M holds f1.X in X by FUNCT_1:111;
      deffunc g(object) = f1.(f.$1);
      consider g such that
      A5:   dom
 g = dom f &
for x being object st x in dom f holds g.x = g(x) from FUNCT_1:sch 3;
      now
        let x be object;
        assume
A6:     x in dom f;
        then
A7:     f.x in M by FUNCT_1:def 3;
        g.x = f1.(f.x) by A5,A6;
        hence g.x in f.x by A4,A7;
      end;
      hence thesis by A1,A5,Def5;
    end;
    hence thesis by A3;
  end;
  assume {} in rng f;
  then
A8: ex x being object st x in dom f & {} = f.x by FUNCT_1:def 3;
  assume
A9: product f <> {};
  set y = the Element of product f;
  ex g st ( y = g)&( dom g = dom f)&( for x being object st x in dom f
  holds g.x in f.x) by A9,Def5;
  hence contradiction by A8;
end;
