
theorem Th26:
  for X be non empty set, Y be ComplexNormSpace st Y is complete
  for seq be sequence of C_NormSpace_of_BoundedFunctions(X,Y) st seq is
  Cauchy_sequence_by_Norm holds seq is convergent
proof
  let X be non empty set;
  let Y be ComplexNormSpace such that
A1: Y is complete;
  let vseq be sequence of C_NormSpace_of_BoundedFunctions(X,Y) such that
A2: vseq is Cauchy_sequence_by_Norm;
  defpred P[set, set] means ex xseq be sequence of Y st
   (for n be Nat holds xseq.n=modetrans((vseq.n),X,Y).$1) &
    xseq is convergent & $2= lim
  xseq;
A3: for x be Element of X ex y be Element of Y st P[x,y]
  proof
    let x be Element of X;
    deffunc F(Nat) = modetrans((vseq.$1),X,Y).x;
    consider xseq be sequence of Y such that
A4: for n be Element of NAT holds xseq.n = F(n) from FUNCT_2:sch 4;
A5: for n be Nat holds xseq.n = F(n)
     proof let n be Nat;
       n in NAT by ORDINAL1:def 12;
      hence thesis by A4;
     end;
    take lim xseq;
A6: for m,k be Nat holds ||.xseq.m-xseq.k.|| <= ||.vseq.m -
    vseq.k.||
    proof
      let m,k be Nat;
A7: k in NAT & m in NAT by ORDINAL1:def 12;
      vseq.k is bounded Function of X,the carrier of Y by Def5;
      then
A8:   modetrans((vseq.k),X,Y)=vseq.k by Th14;
      reconsider h1=vseq.m-vseq.k as bounded Function of X,the carrier of Y by
Def5;
      vseq.m is bounded Function of X,the carrier of Y by Def5;
      then
A9:   modetrans((vseq.m),X,Y)=vseq.m by Th14;
      xseq.m = modetrans((vseq.m),X,Y).x & xseq.k = modetrans((vseq.k),X,
      Y).x by A4,A7;
      then xseq.m - xseq.k = h1.x by A9,A8,Th25;
      hence thesis by Th17;
    end;
    now
      let e be Real such that
A10:   e > 0;
      thus ex k be Nat st for n, m be Nat st n >= k & m
      >= k holds ||.xseq.n -xseq.m.|| < e
      proof
        consider k be Nat such that
A11:     for n, m be Nat st n >= k & m >= k holds ||.(vseq.
        n) - (vseq.m).|| < e by A2,A10,CSSPACE3:8;
        take k;
        thus for n, m be Nat st n >= k & m >= k holds ||.xseq.n-
        xseq.m.|| < e
        proof
          let n,m be Nat;
          assume n >=k & m >= k;
          then
A12:      ||.(vseq.n) - (vseq.m).|| < e by A11;
          ||.xseq.n-xseq.m.|| <= ||.(vseq.n) - (vseq.m).|| by A6;
          hence thesis by A12,XXREAL_0:2;
        end;
      end;
    end;
    then xseq is Cauchy_sequence_by_Norm by CSSPACE3:8;
    then xseq is convergent by A1;
    hence thesis by A5;
  end;
  consider f be Function of X,the carrier of Y such that
A13: for x be Element of X holds P[x,f.x] from FUNCT_2:sch 3(A3);
  reconsider tseq=f as Function of X,the carrier of Y;
  now
    let e1 be Real such that
A14: e1 >0;
    reconsider e =e1 as Real;
    consider k be Nat such that
A15: for n, m be Nat st n >= k & m >= k holds ||.(vseq.n) -
    (vseq.m).|| < e by A2,A14,CSSPACE3:8;
    take k;
    now
      let m be Nat;
      assume m >= k;
      then
A16:  ||.vseq.m.||= ||.vseq.||.m & ||.(vseq.m) - (vseq.k).|| <e by A15,
NORMSP_0:def 4;
      |. ||.vseq.m.||- ||.vseq.k.|| .| <= ||.(vseq.m) - (vseq.k).|| & ||.
      vseq.k .||= ||.vseq.||.k by CLVECT_1:110,NORMSP_0:def 4;
      hence |. ||.vseq.||.m - ||.vseq.||.k .| <e1 by A16,XXREAL_0:2;
    end;
    hence
    for m be Nat st m >= k holds |.||.vseq.||.m - ||.vseq.||
    .k .| < e1;
  end;
  then
A17: ||.vseq.|| is convergent by SEQ_4:41;
A18: tseq is bounded
  proof
    take lim (||.vseq.|| );
A19: now
      let x be Element of X;
      consider xseq be sequence of Y such that
A20:  for n be Nat holds xseq.n=modetrans((vseq.n),X,Y).x and
A21:  xseq is convergent & tseq.x = lim xseq by A13;
A22:  for m be Nat holds ||.xseq.m.|| <= ||.vseq.m.||
      proof
        let m be Nat;
        vseq.m is bounded Function of X,the carrier of Y & xseq.m =
        modetrans((vseq.m ),X,Y).x by A20,Def5;
        hence thesis by Th14,Th17;
      end;
A23:  for n be Nat holds ||.xseq.||.n <=(||.vseq.||).n
      proof
        let n be Nat;
        ||.xseq.||.n = ||.(xseq.n).|| & ||.(xseq.n).|| <= ||.vseq.n.|| by A22,
NORMSP_0:def 4;
        hence thesis by NORMSP_0:def 4;
      end;
      ||.xseq.|| is convergent & ||.tseq.x.|| = lim ||.xseq.|| by A21,
CLOPBAN1:40;
      hence ||.tseq.x.|| <= lim (||.vseq.|| ) by A17,A23,SEQ_2:18;
    end;
    now
      let n be Nat;
      ||.vseq.n.|| >=0 by CLVECT_1:105;
      hence ||.vseq.||.n >=0 by NORMSP_0:def 4;
    end;
    hence thesis by A17,A19,SEQ_2:17;
  end;
A24: for e be Real st e > 0 ex k be Nat st
   for n be Nat st n >= k
 for x be Element of X holds ||.modetrans((vseq.n),X,Y).x - tseq.x.|| <= e
  proof
    let e be Real;
    assume e > 0;
    then consider k be Nat such that
A25: for n, m be Nat st n >= k & m >= k holds ||.(vseq.n) -
    (vseq.m).|| < e by A2,CSSPACE3:8;
    take k;
    now
      let n be Nat such that
A26:  n >= k;
      now
        let x be Element of X;
        consider xseq be sequence of Y such that
A27:    for n be Nat holds xseq.n=modetrans((vseq.n),X,Y). x and
A28:    xseq is convergent & tseq.x = lim xseq by A13;
A29:    for m,k be Nat holds ||.xseq.m-xseq.k.|| <= ||.vseq.m
        - vseq.k.||
        proof
          let m,k be Nat;
          vseq.k is bounded Function of X,the carrier of Y by Def5;
          then
A30:      modetrans((vseq.k),X,Y)=vseq.k by Th14;
          reconsider h1=vseq.m-vseq.k as bounded Function of X,the carrier of
          Y by Def5;
          vseq.m is bounded Function of X,the carrier of Y by Def5;
          then
A31:      modetrans((vseq.m),X,Y)=vseq.m by Th14;
          xseq.m =modetrans((vseq.m),X,Y).x & xseq.k =modetrans((vseq.k),
          X,Y).x by A27;
          then xseq.m - xseq.k =h1.x by A31,A30,Th25;
          hence thesis by Th17;
        end;
A32:    for m be Nat st m >=k holds ||.xseq.n-xseq.m.|| <= e
        proof
          let m be Nat;
          assume m >=k;
          then
A33:      ||.vseq.n - vseq.m.|| <e by A25,A26;
          ||.xseq.n-xseq.m.|| <= ||.vseq.n - vseq.m.|| by A29;
          hence thesis by A33,XXREAL_0:2;
        end;
        ||.xseq.n-tseq.x.|| <= e
        proof
          deffunc F(Nat) = ||.xseq.$1 - xseq.n.||;
          consider rseq be Real_Sequence such that
A34:      for m be Nat holds rseq.m = F(m) from SEQ_1:sch
          1;
          now
            let x be object;
            assume x in NAT;
            then reconsider k=x as Nat;
            thus rseq.x = ||.xseq.k - xseq.n.|| by A34
              .= ||.(xseq - xseq.n).k.|| by NORMSP_1:def 4
              .= ||.(xseq - xseq.n).||.x by NORMSP_0:def 4;
          end;
          then
A35:      rseq = ||.xseq - xseq.n.|| by FUNCT_2:12;
A36:      xseq - xseq.n is convergent & lim (xseq-xseq.n)= tseq.x - xseq.
          n by A28,CLVECT_1:115,121;
          then
A37:      lim rseq = ||.tseq.x-xseq.n.|| by A35,CLOPBAN1:19;
          for m be Nat st m >= k holds rseq.m <= e
          proof
            let m be Nat such that
A38:        m >=k;
            rseq.m = ||.xseq.m-xseq.n.|| by A34
              .= ||.xseq.n-xseq.m.|| by CLVECT_1:108;
            hence thesis by A32,A38;
          end;
          then lim rseq <= e by A36,A35,Lm12,CLOPBAN1:19;
          hence thesis by A37,CLVECT_1:108;
        end;
        hence ||.modetrans((vseq.n),X,Y).x - tseq.x.|| <= e by A27;
      end;
      hence for x be Element of X holds ||.modetrans((vseq.n),X,Y).x - tseq.x
      .|| <= e;
    end;
    hence thesis;
  end;
  reconsider tseq as bounded Function of X,the carrier of Y by A18;
  reconsider tv=tseq as Point of C_NormSpace_of_BoundedFunctions(X,Y) by Def5;
A39: for e be Real st e > 0 ex k be Nat
    st for n be Nat st n >= k holds ||.vseq.n - tv.|| <= e
  proof
    let e be Real;
    assume e > 0;
    then consider k be Nat such that
A40: for n be Nat st n >= k holds for x be Element of X
    holds ||.modetrans((vseq.n),X,Y).x - tseq.x.|| <= e by A24;
    now
      set g1=tseq;
      let n be Nat such that
A41:  n >= k;
      reconsider h1=vseq.n-tv as bounded Function of X,the carrier of Y by Def5
;
      set f1=modetrans((vseq.n),X,Y);
A42:  now
        let t be Element of X;
        vseq.n is bounded Function of X,the carrier of Y by Def5;
        then modetrans((vseq.n),X,Y)=vseq.n by Th14;
        then ||.h1.t.||= ||.f1.t-g1.t.|| by Th25;
        hence ||.h1.t.|| <=e by A40,A41;
      end;
A43:  now
        let r be Real;
        assume r in PreNorms(h1);
        then ex t be Element of X st r=||.h1.t.||;
        hence r <=e by A42;
      end;
A44:  (for s be Real st s in PreNorms(h1) holds s <= e) implies
      upper_bound PreNorms(h1) <=e by SEQ_4:45;
      ComplexBoundedFunctionsNorm(X,Y).(vseq.n-tv) = upper_bound PreNorms(h1)
       by Th15;
      hence ||.vseq.n-tv.|| <=e by A43,A44;
    end;
    hence thesis;
  end;
  for e be Real st e > 0 ex m be Nat st
   for n be Nat st n >= m holds ||.(vseq.n) - tv.|| < e
  proof
    let e be Real such that
A45: e > 0;
    reconsider ee=e as Real;
    consider m be Nat such that
A46: for n be Nat st n >= m holds ||.(vseq.n) - tv.|| <= ee/
    2 by A39,A45;
A47: e/2<e by A45,XREAL_1:216;
    now
      let n be Nat;
      assume n >= m;
      then ||.(vseq.n) - tv.|| <= e/2 by A46;
      hence ||.(vseq.n) - tv.|| < e by A47,XXREAL_0:2;
    end;
    hence thesis;
  end;
  hence thesis by CLVECT_1:def 15;
end;
