reserve x for object;
reserve x0,r,r1,r2,g,g1,g2,p,y0 for Real;
reserve n,m,k,l for Element of NAT;
reserve a,b,d for Real_Sequence;
reserve h,h1,h2 for non-zero 0-convergent Real_Sequence;
reserve c,c1 for constant Real_Sequence;
reserve A for open Subset of REAL;
reserve f,f1,f2 for PartFunc of REAL,REAL;
reserve L for LinearFunc;
reserve R for RestFunc;

theorem
  left_open_halfline(r) c= dom f &
  (for r1,r2 st r1 in left_open_halfline(r) &
  r2 in left_open_halfline(r) holds |.f.r1 - f.r2.| <= (r1 - r2)^2)
    implies f is_differentiable_on left_open_halfline(r) &
            f|left_open_halfline r is constant
proof
  assume that
A1: left_open_halfline(r) c= dom f and
A2: for r1,r2 st r1 in left_open_halfline(r) & r2 in left_open_halfline(
  r) holds |.f.r1 - f.r2.| <= (r1 - r2)^2;
  now
    let r1,r2 be Element of REAL;
    assume that
A3: r1 in left_open_halfline(r) /\ dom f and
A4: r2 in left_open_halfline(r) /\ dom f;
    set rr = min(r1,r2);
A5: ].rr - 1, r.[ c= left_open_halfline(r) by XXREAL_1:263;
    then
A6: for g1,g2 st g1 in ].rr - 1, r.[ & g2 in ].rr - 1, r.[ holds |.f.g1
    - f.g2.| <= (g1 - g2)^2 by A2;
    r2 in left_open_halfline(r) by A4,XBOOLE_0:def 4;
    then r2 in {p: p < r} by XXREAL_1:229;
    then
A7: ex g2 st g2 = r2 & g2 < r;
    rr - 1 < r2 - 0 by XREAL_1:15,XXREAL_0:17;
    then r2 in {g2: rr - 1 < g2 & g2 < r} by A7;
    then
A8: r2 in ].rr - 1, r.[ by RCOMP_1:def 2;
    r2 in dom f by A4,XBOOLE_0:def 4;
    then
A9: r2 in ].rr - 1, r.[ /\ dom f by A8,XBOOLE_0:def 4;
    r1 in left_open_halfline(r) by A3,XBOOLE_0:def 4;
    then r1 in {g: g < r} by XXREAL_1:229;
    then
A10: ex g1 st g1 = r1 & g1 < r;
    rr - 1 < r1 - 0 by XREAL_1:15,XXREAL_0:17;
    then r1 in {g1: rr - 1 < g1 & g1 < r} by A10;
    then
A11: r1 in ].rr - 1, r.[ by RCOMP_1:def 2;
    r1 in dom f by A3,XBOOLE_0:def 4;
    then
A12: r1 in ].rr - 1, r.[ /\ dom f by A11,XBOOLE_0:def 4;
    ].rr - 1, r.[ c= dom f by A1,A5;
    then f|].rr-1,r.[ is constant by A6,Th25;
    hence f.r1 = f.r2 by A12,A9,PARTFUN2:58;
  end;
  hence thesis by A1,A2,Th24,PARTFUN2:58;
end;
