
theorem
for F being strong_polynomial_disjoint Field,
    p being irreducible Element of the carrier of Polynom-Ring F
for E being Field st E = embField(emb p) holds E is strong_polynomial_disjoint
proof
let F be strong_polynomial_disjoint Field,
    p be irreducible Element of the carrier of Polynom-Ring F;
let E be Field;
assume AS: E = embField(emb p);
set FX = Polynom-Ring F, EX = Polynom-Ring E, f = emb p,
    Kr = KroneckerField(F,p);
X: [#] F = the carrier of F & [#] Kr = the carrier of Kr;
H: the carrier of E
 = carr f by AS,FIELD_2:def 7
.= ((the carrier of Kr)\(rng f))\/(the carrier of F) by X,FIELD_2:def 2;
now assume E is non strong_polynomial_disjoint;
  then consider o being Element of E,
                S being Ring,
                q being Element of the carrier of Polynom-Ring S such that
  K: o = q;
  set SX = Polynom-Ring S;
  per cases by H,XBOOLE_0:def 3;
  suppose o in the carrier of F;
    hence contradiction by K,dspd;
    end;
  suppose o in (the carrier of Kr) \ (rng f); then
    reconsider o as Element of (Polynom-Ring F)/({p}-Ideal);
    consider a being Element of Polynom-Ring F such that
    B: o = Class(EqRel(Polynom-Ring F,{p}-Ideal),a) by RING_1:11;
    reconsider q as Polynomial of S;
    a - a = 0.(Polynom-Ring F) by RLVECT_1:15; then
    D0: a in q by K,B,RING_1:5,IDEAL_1:3; then
    consider i,z being object such that
    D1: i in NAT & z in the carrier of S & a = [i,z] by ZFMISC_1:def 2;
    D2: z = q.i by D0,D1,FUNCT_1:1;
    reconsider i as Element of NAT by D1;
    reconsider a as Polynomial of F by POLYNOM3:def 10;
    dom a = NAT by FUNCT_2:def 1; then
    [1,a.1] in a & [2,a.2] in a by FUNCT_1:1; then
    E: [1,a.1] in {{i},{i,q.i}} & [2,a.2] in {{i},{i,q.i}}
       by D1,D2,TARSKI:def 5;
  F: now assume E3: i = {1};
     per cases by E,TARSKI:def 2;
     suppose [2,a.2] = {i};
          then F1: {i} = {{2},{2,a.2}} by TARSKI:def 5;
          {2} in {{2},{2,a.2}} by TARSKI:def 2;
          then F3: {2} = {1} by E3,F1,TARSKI:def 1;
          2 in {2} by TARSKI:def 1;
          hence contradiction by F3,TARSKI:def 1;
          end;
     suppose [2,a.2] = {i,q.i};
          then F1: {i,q.i} = {{2},{2,a.2}} by TARSKI:def 5;
          i in {i,q.i} by TARSKI:def 2; then
        per cases by F1,TARSKI:def 2;
        suppose F3: i = {2};
            2 in {2} by TARSKI:def 1;
            hence contradiction by E3,F3,TARSKI:def 1;
            end;
        suppose F3: i = {2,a.2};
            2 in {2,a.2} by TARSKI:def 2;
            hence contradiction by E3,F3,TARSKI:def 1;
            end;
        end;
      end;
    per cases by E,TARSKI:def 2;
    suppose [1,a.1] = {i};
      then E1: {i} = {{1},{1,a.1}} by TARSKI:def 5;
      {1} in {{1},{1,a.1}} & {1,a.1} in {{1},{1,a.1}} by TARSKI:def 2;
      hence contradiction by F,E1,TARSKI:def 1;
      end;
    suppose [1,a.1] = {i,q.i}; then
      E1: {i,q.i} = {{1},{1,a.1}} by TARSKI:def 5;
      i in {i,q.i} by TARSKI:def 2; then
      F0: i = {1,a.1} by F,E1,TARSKI:def 2;
        per cases;
        suppose E3: 1 = a.1;
          per cases by E,TARSKI:def 2;
          suppose [2,a.2] = {i};
            then F1: {i} = {{2},{2,a.2}} by TARSKI:def 5;
            {2} in {{2},{2,a.2}} by TARSKI:def 2;
            then F3: {2} = i by F1,TARSKI:def 1
                        .= {1} by E3,F0,ENUMSET1:29;
            2 in {2} by TARSKI:def 1;
            hence contradiction by F3,TARSKI:def 1;
            end;
          suppose [2,a.2] = {i,q.i};
            then F1: {i,q.i} = {{2},{2,a.2}} by TARSKI:def 5;
            i in {i,q.i} by TARSKI:def 2; then
            per cases by F1,TARSKI:def 2;
            suppose i = {2};
              then F3: {2} = {1} by E3,F0,ENUMSET1:29;
              2 in {2} by TARSKI:def 1;
              hence contradiction by F3,TARSKI:def 1;
              end;
            suppose i = {2,a.2};
              then F3: {1} = {2,a.2} by E3,F0,ENUMSET1:29;
              2 in {2,a.2} by TARSKI:def 2;
              hence contradiction by F3,TARSKI:def 1;
              end;
            end;
          end;
        suppose G: 1 <> a.1;
        G1: a.1 = 0 by F0,G,FIELD_3:2;
        per cases by E,TARSKI:def 2;
        suppose [2,a.2] = {i};
          then F1: {{1,a.1}} = {{2},{2,a.2}} by F0,TARSKI:def 5;
          {2} in {{2},{2,a.2}} & {2,a.2} in {{2},{2,a.2}} by TARSKI:def 2;
          hence contradiction by G1,F1,CARD_1:50;
          end;
        suppose [2,a.2] = {i,q.i};
          then F1: {2,q.i} = {{2},{2,a.2}} by CARD_1:50,F0,G1,TARSKI:def 5;
          2 in {2,q.i} by TARSKI:def 2; then
          per cases by F1,TARSKI:def 2;
          suppose F2: 2 = {2};
            2 in {2} by TARSKI:def 1;
            hence contradiction by F2;
            end;
          suppose F2: 2 = {2,a.2};
            2 in {2,a.2} by TARSKI:def 2;
            hence contradiction by F2;
            end;
          end;
        end;
      end;
    end;
  end;
hence thesis;
end;
