
theorem Th26:
  for G1 being non _trivial _Graph, v0,v1 being Vertex of G1
  for G2 being removeVertex of G1, v0, v2 being Vertex of G2
  st v1 = v2 & not v1 in G1.reachableFrom(v0)
  holds G2.reachableFrom(v2) = G1.reachableFrom(v1)
proof
  let G1 be non _trivial _Graph, v0,v1 be Vertex of G1;
  let G2 be removeVertex of G1, v0, v2 be Vertex of G2;
  assume A1: v1 = v2 & not v1 in G1.reachableFrom(v0);
  then A2: G2.reachableFrom(v2) c= G1.reachableFrom(v1) by GLIB_002:14;
  for w being object holds w in G1.reachableFrom(v1)
    implies w in G2.reachableFrom(v2)
  proof
    let w be object;
    assume w in G1.reachableFrom(v1);
    then consider W being Walk of G1 such that
      A3: W is_Walk_from v1, w by GLIB_002:def 5;
    not v0 in W.vertices()
    proof
      assume A4: v0 in W.vertices();
      reconsider m = 1 as odd Element of NAT by POLYFORM:4;
      reconsider n = W.find(v0) as odd Element of NAT;
      set U = W.cut(m,n);
      m <= n & n <= len W by A4, GLIB_001:def 19, CHORD:2;
      then U is_Walk_from W.m, W.n by GLIB_001:37;
      then U is_Walk_from W.first(), W.n by GLIB_001:def 6;
      then U is_Walk_from v1, W.n by A3, GLIB_001:def 23;
      then U is_Walk_from v1, v0 by A4, GLIB_001:def 19;
      then U.reverse() is_Walk_from v0, v1 by GLIB_001:23;
      hence contradiction by A1, GLIB_002:def 5;
    end;
    then reconsider W2 = W as Walk of G2 by GLIB_001:171;
    W2 is_Walk_from v2, w by A1, A3, GLIB_001:19;
    hence w in G2.reachableFrom(v2) by GLIB_002:def 5;
  end;
  then G1.reachableFrom(v1) c= G2.reachableFrom(v2) by TARSKI:def 3;
  hence thesis by A2, XBOOLE_0:def 10;
end;
