reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th26:
  1 <= i & i < len G & 1 <= j & j < width G implies Int cell(G,i,j
) = { |[r,s]| : G*(i,1)`1 < r & r < G*(i+1,1)`1 & G*(1,j)`2 < s & s < G*(1,j+1)
  `2 }
proof
  assume that
A1: 1 <= i & i < len G and
A2: 1 <= j & j < width G;
A3: Int h_strip(G,j) = { |[r,s]| : G*(1,j)`2 < s & s < G* (1,j+1)`2 } by A2
,Th17;
  cell(G,i,j) = v_strip(G,i) /\ h_strip(G,j) by GOBOARD5:def 3;
  then
A4: Int cell(G,i,j) = Int v_strip(G,i) /\ Int h_strip(G,j) by TOPS_1:17;
A5: Int v_strip(G,i) = { |[r,s]| : G*(i,1)`1 < r & r < G* (i+1,1)`1 } by A1
,Th14;
  thus Int cell(G,i,j) c= { |[r,s]| : G*(i,1)`1 < r & r < G*(i+1,1)`1 & G*(1,j
  )`2 < s & s < G*(1,j+1)`2 }
  proof
    let x be object;
    assume
A6: x in Int cell(G,i,j);
    then x in Int v_strip(G,i) by A4,XBOOLE_0:def 4;
    then consider r1,s1 such that
A7: x = |[r1,s1]| and
A8: G*(i,1)`1 < r1 & r1 < G*(i+1,1)`1 by A5;
    x in Int h_strip(G,j) by A4,A6,XBOOLE_0:def 4;
    then consider r2,s2 such that
A9: x = |[r2,s2]| and
A10: G*(1,j)`2 < s2 & s2 < G*(1,j+1)`2 by A3;
    s1 = s2 by A7,A9,SPPOL_2:1;
    hence thesis by A7,A8,A10;
  end;
  let x be object;
  assume x in { |[r,s]| : G*(i,1)`1 < r & r < G*(i+1,1)`1 & G*(1,j)`2 < s &
  s < G*(1,j+1)`2 };
  then
A11: ex r,s st x = |[r,s]| & G*(i,1)`1 < r & r < G*(i+1,1)`1 & G*(1,j)`2 < s
  & s < G*(1,j+1)`2;
  then
A12: x in Int h_strip(G,j) by A3;
  x in Int v_strip(G,i) by A5,A11;
  hence thesis by A4,A12,XBOOLE_0:def 4;
end;
