reserve i,j,k,i1,j1 for Nat,
  p for Point of TOP-REAL 2,
  x for set;
reserve f for non constant standard special_circular_sequence;
reserve P for Subset of TOP-REAL 2;

theorem
  LSeg((GoB f)*(1,1)- |[1,1]|,1/2*((GoB f)*(1,1)+(GoB f)*(2,1))- |[0,1]|
  ) misses L~f
proof
A1: 1 <= width GoB f by GOBOARD7:33;
  now
    1 < len GoB f by GOBOARD7:32;
    then 1+1 <= len GoB f by NAT_1:13;
    then
A2: (GoB f)*(2,1)`2 = (GoB f)*(1,1)`2 by A1,GOBOARD5:1;
    (1/2*((GoB f)*(1,1)+(GoB f)*(2,1))- |[0,1]|)`2 = (1/2*((GoB f)*(1,1)+(
    GoB f)*(2,1)))`2- |[0,1]|`2 by TOPREAL3:3
      .= 1/2*((GoB f)*(1,1)+(GoB f)*(2,1))`2- |[0,1]|`2 by TOPREAL3:4
      .= 1/2*((GoB f)*(1,1)`2+(GoB f)*(1,1)`2)- |[0,1]|`2 by A2,TOPREAL3:2
      .= 1*((GoB f)*(1,1))`2-1 by EUCLID:52;
    then
A3: 1/2*((GoB f)*(1,1)+(GoB f)*(2,1))- |[0,1]| = |[(1/2*((GoB f)*(1,1)+(
    GoB f)*(2,1))- |[0,1]|)`1, (GoB f)*(1,1)`2-1]| by EUCLID:53;
    ((GoB f)*(1,1)- |[1,1]|)`2 = ((GoB f)*(1,1))`2- |[1,1]|`2 by TOPREAL3:3
      .= (GoB f)*(1,1)`2-1 by EUCLID:52;
    then
A4: (GoB f)*(1,1)- |[1,1]| = |[((GoB f)*(1,1)- |[1,1]|)`1,(GoB f)*(1,1)`2-
    1]| by EUCLID:53;
    let p;
    assume p in LSeg((GoB f)*(1,1)- |[1,1]|, 1/2*((GoB f)*(1,1)+(GoB f)*(2,1)
    )- |[0,1]|);
    then p`2 = (GoB f)*(1,1)`2 - 1 by A4,A3,TOPREAL3:12;
    hence p`2 < (GoB f)*(1,1)`2 by XREAL_1:44;
  end;
  hence thesis by Th23;
end;
