reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;

theorem Th26:
  A c= B implies the_stable_subgroup_of A is StableSubgroup of
  the_stable_subgroup_of B
proof
  assume
A1: A c= B;
  per cases;
  suppose
A2: A is empty;
    reconsider H1 = (1).G,H2 = (1).(the_stable_subgroup_of B) as strict
    StableSubgroup of G by Th11;
    the carrier of H1 = {1_G} by Def8
      .= {1_(the_stable_subgroup_of B)} by Th4
      .= the carrier of H2 by Def8;
    then (1).G = (1).(the_stable_subgroup_of B) by Lm4;
    hence thesis by A2,Lm24;
  end;
  suppose
A3: A is not empty;
    now
      set D = the_stable_subset_generated_by (B, the action of G);
      let a be Element of G;
      assume a in the_stable_subgroup_of A;
      then consider
      F be FinSequence of the carrier of G, I be FinSequence of INT,
      C be Subset of G such that
A4:   C = the_stable_subset_generated_by (A, the action of G) and
A5:   len F = len I and
A6:   rng F c= C and
A7:   Product(F |^ I) = a by Th24;
      now
        let y be object;
        assume
A8:     y in C;
        then reconsider b=y as Element of G;
        consider F1 be FinSequence of O, x be Element of A such that
A9:     Product(F1,the action of G).x = b by A3,A4,A8,Lm30;
        x in A by A3;
        hence y in D by A1,A9,Lm30;
      end;
      then C c= D;
      then rng F c= D by A6;
      hence a in the_stable_subgroup_of B by A5,A7,Th24;
    end;
    hence thesis by Th13;
  end;
end;
