
theorem
  for V be non empty VectSp of F_Complex for l be linear-Functional of V
  holds projIm(l) is linear-Functional of RealVS(V)
proof
  let V be non empty VectSp of F_Complex;
  let l be linear-Functional of V;
A1: projIm(l) is homogeneous
  proof
    let x be VECTOR of RealVS(V);
    let r be Real;
    the addLoopStr of V = the addLoopStr of RealVS(V) by Def17;
    then reconsider x1=x as Vector of V;
    r*x = [**r,0**]*x1 by Def17;
    hence (projIm(l)).(r*x) = Im(l.([**r,0**]*x1)) by Def19
      .= Im([**r,0**]*l.x1) by Def8
      .= Re [**r,0**] * Im (l.x1) + Re (l.x1) * Im [**r,0**] by COMPLEX1:9
      .= Re [**r,0**] * Im (l.x1) + Re (l.x1) * 0 by COMPLEX1:12
      .= r * Im (l.x1) by COMPLEX1:12
      .= r*(projIm(l)).x by Def19;
  end;
  projIm(l) is additive
  proof
    let x,y be VECTOR of RealVS(V);
A2: the addLoopStr of V = the addLoopStr of RealVS(V) by Def17;
    then reconsider x1=x, y1=y as Vector of V;
    thus (projIm(l)).(x+y) = Im(l.(x1+y1)) by A2,Def19
      .= Im(l.x1+l.y1) by VECTSP_1:def 20
      .= Im(l.x1)+Im(l.y1) by COMPLEX1:8
      .= Im(l.x1)+(projIm(l)).y by Def19
      .= (projIm(l)).x+(projIm(l)).y by Def19;
  end;
  hence thesis by A1;
end;
