reserve Z for RealNormSpace;
reserve a,b,c,d,e,r for Real;
reserve A,B for non empty closed_interval Subset of REAL;
reserve X,Y for RealBanachSpace;
reserve E for Point of Y;

theorem Th404:
  for Y be RealNormSpace,
      A be non empty closed_interval Subset of REAL,
      f be Function of A,the carrier of Y,
      E be Point of Y
  st rng f = {E} holds f is integrable & integral f = (vol A) * E
proof
   let Y be RealNormSpace;
   let A be non empty closed_interval Subset of REAL;
   let f be Function of A,the carrier of Y;
   let E be Point of Y;
   assume AS1: rng f = {E};
   reconsider I = (vol A) * E as Point of Y;
P1:for T being DivSequence of A,
       S be middle_volume_Sequence of f,T st
    delta T is convergent & lim delta T = 0 holds
      middle_sum(f,S) is convergent & lim middle_sum(f,S) = I
   proof
    let T be DivSequence of A,
        S be middle_volume_Sequence of f,T;
    assume delta T is convergent & lim delta T = 0;
    set s = middle_sum(f,S);
A1: for k being Nat holds s.k = I
    proof
     let k be Nat;
     defpred P11[Nat,set] means $2 = vol divset(T.k,$1);
A14: for i be Nat st i in Seg len (T.k) holds
       ex x be Element of REAL st P11[i,x]
     proof
      let i be Nat;
      assume i in Seg len (T.k);
      vol divset(T.k,i) in REAL by XREAL_0:def 1;
      hence thesis;
     end;
     consider q be FinSequence of REAL such that
A18:  dom q = Seg len (T.k)
    & for i be Nat st i in Seg len (T.k) holds P11[i,q.i]
         from FINSEQ_1:sch 5(A14);
B7:  Sum q = vol A by INTEGR20:6,A18;
     len q = len (T.k) by A18,FINSEQ_1:def 3; then
B8:  len (S.k) = len q by INTEGR18:def 1;
B40: for i be Nat st i in dom (S.k) holds
      ex r be Real st r =q.i & (S.k).i= r * E
     proof
      let i be Nat;
      assume i in dom (S.k); then
      i in Seg len (S.k) by FINSEQ_1:def 3; then
B44:  i in Seg len (T.k) by INTEGR18:def 1; then
      i in dom (T.k) by FINSEQ_1:def 3; then
      consider c be Point of Y such that
B42:   c in rng (f|divset(T.k,i))
     & (S.k).i= (vol divset(T.k,i)) * c by INTEGR18:def 1;
      c in rng f by B42,TARSKI:def 3,RELAT_1:70; then
B43:  c = E by AS1,TARSKI:def 1;
      q.i = vol divset(T.k,i) by A18,B44;
      hence thesis by B42,B43;
     end;
     s.k = middle_sum(f,S.k) by INTEGR18:def 4;
     hence thesis by B40,B7,B8,INTEGR20:7;
    end;
A2: now let p be Real;
     assume A3: 0<p;
     reconsider k = 0 as Nat;
     take k;
     let n be Nat such that k<=n;
     thus ||.s.n - I.|| < p by A3,NORMSP_1:6,A1;
    end;
    hence s is convergent;
    hence thesis by A2,NORMSP_1:def 7;
   end;
   hence f is integrable;
   hence integral f = (vol A) * E by P1,INTEGR18:def 6;
end;
