reserve r,p,x for Real;
reserve n for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;

theorem
  for f1,f2,g being PartFunc of REAL,REAL, A being non empty closed_interval
  Subset of REAL st (f1(#)g)||A is total & (f2(#)g)||A is total & (f1(#)g)||A|A
is bounded & (f1(#)g)||A is integrable & (f2(#)g)||A|A is bounded & (f2(#)g)||A
  is integrable holds |||(f1-f2,g,A)||| = |||(f1,g,A)||| - |||(f2,g,A)|||
proof
  let f1,f2,g be PartFunc of REAL,REAL;
  let A be non empty closed_interval Subset of REAL;
  assume
A1: (f1(#)g)||A is total & (f2(#)g)||A is total;
  assume
A2: (f1(#)g)||A|A is bounded & (f1(#)g)||A is integrable & (f2(#)g)||A|A
  is bounded & (f2(#)g)||A is integrable;
  |||(f1-f2,g,A)||| = integral(((f1-f2)||A)(#)(g||A)) by INTEGRA5:4
    .= integral(((f1(#)g)-(f2(#)g))||A) by Th22
    .= integral(((f1(#)g)||A)-((f2(#)g)||A)) by Th20
    .= integral((f1(#)g)||A) - integral((f2(#)g)||A) by A1,A2,INTEGRA2:33;
  hence thesis;
end;
