reserve p,q for Point of TOP-REAL 2;

theorem Th26:
  for cn being Real,q being Point of TOP-REAL 2 st -1<cn & cn<1 &
q`2<0 & q`1/|.q.|>cn holds for p being Point of TOP-REAL 2 st p=(cn-FanMorphS).
  q holds p`2<0 & p`1>0
proof
  let cn be Real,q be Point of TOP-REAL 2;
  assume that
A1: -1<cn and
A2: cn<1 and
A3: q`2<0 and
A4: q`1/|.q.|>cn;
  let p be Point of TOP-REAL 2;
  assume
A5: p=(cn-FanMorphS).q;
  now
    set q1=(|.p.|)*|[cn,-sqrt(1-cn^2)]|;
    set p1=(1/|.p.|)*p;
    set p2=(cn-FanMorphS).q1;
    (|[0,-1]|)`1=0 & (|[0,-1]|)`2=-1 by EUCLID:52;
    then
A6: |.p.|*(|[0,-1]|)=|[|.p.|*0,|.p.|*(-1)]| by EUCLID:57
      .=|[0,-(|.p.|)]|;
A7: (|[cn,-sqrt(1-cn^2)]|)`1=cn & (|[cn,-sqrt(1-cn^2)]|)`2=-sqrt(1-cn^2)
    by EUCLID:52;
    then
A8: q1=|[|.p.|*cn,|.p.|*(-sqrt(1-cn^2))]| by EUCLID:57;
    then
A9: q1`1=(|.p.|)*cn by EUCLID:52;
    assume
A10: p`1=0;
    then (|.p.|)^2=(p`2)^2+0^2 by JGRAPH_3:1
      .=(p`2)^2;
    then
A11: p`2=|.p.| or p`2= - |.p.| by SQUARE_1:40;
    then
A12: |.p.| <> 0 by A2,A3,A4,A5,JGRAPH_4:137;
A13: q1`2=-(sqrt(1-cn^2)*(|.p.|)) by A8,EUCLID:52;
    1^2>cn^2 by A1,A2,SQUARE_1:50;
    then
A14: 1-cn^2>0 by XREAL_1:50;
    then sqrt(1-cn^2)>0 by SQUARE_1:25;
    then --sqrt(1-cn^2)*(|.p.|)>0 by A12,XREAL_1:129;
    then
A15: q1`2<0 by A13;
A16: |.p.|*p1=(|.p.|*(1/|.p.|))*p by RLVECT_1:def 7
      .=(1)*p by A12,XCMPLX_1:106
      .=p by RLVECT_1:def 8;
A17: p1=|[(1/|.p.|)*p`1,(1/|.p.|)*p`2]| by EUCLID:57;
    then p1`2=-(|.p.|*(1/ |.p.|)) by A2,A3,A4,A5,A11,EUCLID:52,JGRAPH_4:137
      .=-1 by A12,XCMPLX_1:106;
    then
A18: p=|.p.|*(|[0,-1]|) by A10,A16,A17,EUCLID:52;
A19: |.q1.|=|.|.p.|.|*|.(|[cn,-sqrt(1-cn^2)]|).| by TOPRNS_1:7
      .=|.|.p.|.|*sqrt((cn)^2+(-sqrt(1-cn^2))^2) by A7,JGRAPH_3:1
      .=|.|.p.|.|*sqrt(cn^2+(sqrt(1-cn^2))^2)
      .=|.|.p.|.|*sqrt(cn^2+(1-cn^2)) by A14,SQUARE_1:def 2
      .=|.p.| by ABSVALUE:def 1;
    then
A20: |.p2.|=|.p.| by JGRAPH_4:128;
A21: q1`1/|.q1.|=cn by A12,A9,A19,XCMPLX_1:89;
    then
A22: p2`1=0 by A15,JGRAPH_4:142;
    then (|.p2.|)^2=(p2`2)^2+0^2 by JGRAPH_3:1
      .=(p2`2)^2;
    then p2`2=|.p2.| or p2`2= - |.p2.| by SQUARE_1:40;
    then
A23: p2=|[0,-(|.p.|)]| by A15,A21,A22,A20,EUCLID:53,JGRAPH_4:142;
    (cn-FanMorphS) is one-to-one & dom (cn-FanMorphS)=the carrier of
    TOP-REAL 2 by A1,A2,FUNCT_2:def 1,JGRAPH_4:133;
    then q1=q by A5,A18,A23,A6,FUNCT_1:def 4;
    hence contradiction by A4,A12,A9,A19,XCMPLX_1:89;
  end;
  hence thesis by A2,A3,A4,A5,JGRAPH_4:137;
end;
