reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th26:
  for Kb,Cb being Subset of TOP-REAL 2 st
  Kb={p: not(-1 <=p`1 & p`1<= 1 & -1 <=p`2 & p`2<= 1)}&
  Cb={p2 where p2 is Point of TOP-REAL 2: |.p2.|>1} holds Sq_Circ.:Kb=Cb
proof
  let Kb,Cb be Subset of TOP-REAL 2;
  assume
A1: Kb={p: not(-1 <=p`1 & p`1<= 1 & -1 <=p`2 & p`2<= 1)}&
  Cb={p2 where p2 is Point of TOP-REAL 2: |.p2.|>1};
  thus Sq_Circ.:Kb c= Cb
  proof
    let y be object;
    assume y in Sq_Circ.:Kb;
    then consider x being object such that
    x in dom Sq_Circ and
A2: x in Kb and
A3: y=Sq_Circ.x by FUNCT_1:def 6;
    consider q being Point of TOP-REAL 2 such that
A4: q=x and
A5: not(-1 <=q`1 & q`1<= 1 & -1 <=q`2 & q`2<= 1) by A1,A2;
    now per cases;
      case q=0.TOP-REAL 2;
        hence contradiction by A5,EUCLID:52,54;
      end;
      case
A6:     q<>0.TOP-REAL 2 & (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
        then
        A7:     Sq_Circ.q=|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2 )]|
        by JGRAPH_3:def 1;
A8:     not(-1 <=q`2 & q`2<= 1) implies -1>q`1 or q`1>1
        proof
          assume
A9:       not(-1 <=q`2 & q`2<= 1);
          now per cases by A9;
            case
A10:          -1>q`2;
              then -q`1< -1 or q`2>=q`1 & q`2<= -q`1 by A6,XXREAL_0:2;
              hence thesis by A10,XREAL_1:24,XXREAL_0:2;
            end;
            case q`2>1;
              then 1<q`1 or 1< -q`1 by A6,XXREAL_0:2;
              then 1<q`1 or --q`1< -1 by XREAL_1:24;
              hence thesis;
            end;
          end;
          hence thesis;
        end;
A11:    (|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|)`1 = q`1/sqrt(1+(q
        `2/q`1)^2) by EUCLID:52;
A12:    (|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|)`2 = q`2/sqrt(1+(q
        `2/q`1)^2) by EUCLID:52;
A13:    1+(q`2/q`1)^2>0 by XREAL_1:34,63;
A14:    now
          assume
A15:      q`1=0;
          then q`2=0 by A6;
          hence contradiction by A6,A15,EUCLID:53,54;
        end;
        then
A16:    (q`1)^2>0 by SQUARE_1:12;
        (q`1)^2>1^2 by A5,A8,SQUARE_1:47;
        then
A17:    sqrt((q`1)^2)>1 by SQUARE_1:18,27;
        |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|^2
        =((q`1)/sqrt(1+(q`2/(q`1))^2))^2+(q`2/sqrt(1+(q`2/(q`1))^2))^2
        by A11,A12,JGRAPH_3:1
          .=(q`1)^2/(sqrt(1+(q`2/(q`1))^2))^2+(q`2/sqrt(1+(q`2/(q`1))^2))^2
        by XCMPLX_1:76
          .=(q`1)^2/(sqrt(1+(q`2/(q`1))^2))^2
        +(q`2)^2/(sqrt(1+(q`2/(q`1))^2))^2 by XCMPLX_1:76
          .=(q`1)^2/(1+(q`2/q`1)^2)+(q`2)^2/(sqrt(1+(q`2/q`1)^2))^2
        by A13,SQUARE_1:def 2
          .=(q`1)^2/(1+(q`2/q`1)^2)+(q`2)^2/(1+(q`2/q`1)^2)
        by A13,SQUARE_1:def 2
          .=((q`1)^2+(q`2)^2)/(1+(q`2/q`1)^2) by XCMPLX_1:62
          .=((q`1)^2+(q`2)^2)/(1+(q`2)^2/(q`1)^2) by XCMPLX_1:76
          .=((q`1)^2+(q`2)^2)/((q`1)^2/(q`1)^2+(q`2)^2/(q`1)^2)
        by A16,XCMPLX_1:60
          .=((q`1)^2+(q`2)^2)/(((q`1)^2+(q`2)^2)/(q`1)^2) by XCMPLX_1:62
          .=(q`1)^2*(((q`1)^2+(q`2)^2)/((q`1)^2+(q`2)^2)) by XCMPLX_1:81
          .=(q`1)^2*1 by A14,COMPLEX1:1,XCMPLX_1:60
          .=(q`1)^2;
        then |.(|[q`1/sqrt(1+(q`2/q`1)^2),q`2/sqrt(1+(q`2/q`1)^2)]|).|>1
        by A17,SQUARE_1:22;
        hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|>1 by A3,A4,A7;
      end;
      case
A18:    q<>0.TOP-REAL 2 & not(q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
        then
A19:    Sq_Circ.q=|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2 )]|
        by JGRAPH_3:def 1;
A20:    (|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|)`1 = q`1/sqrt(1+(q
        `1/q`2)^2) by EUCLID:52;
A21:    (|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|)`2 = q`2/sqrt(1+(q
        `1/q`2)^2) by EUCLID:52;
A22:    1+(q`1/q`2)^2>0 by XREAL_1:34,63;
A23:    q`2 <> 0 by A18;
        then
A24:    (q`2)^2>0 by SQUARE_1:12;
        not(-1 <=q`1 & q`1<= 1) implies -1>q`2 or q`2>1
        proof
          assume
A25:      not(-1 <=q`1 & q`1<= 1);
          now per cases by A25;
            case
A26:          -1>q`1;
then q`2< -1 or q`1<q`2 & -q`2< --q`1 by A18,XREAL_1:24,XXREAL_0:2;
              then -q`2< -1 or -1>q`2 by A26,XXREAL_0:2;
              hence thesis by XREAL_1:24;
            end;
            case
A27:          q`1>1;
              --q`1< -q`2 & q`2<q`1 or q`2>q`1 & q`2> -q`1 by A18,XREAL_1:24;
              then 1< -q`2 or q`2>q`1 & q`2> -q`1 by A27,XXREAL_0:2;
              then -1> --q`2 or 1<q`2 by A27,XREAL_1:24,XXREAL_0:2;
              hence thesis;
            end;
          end;
          hence thesis;
        end;
        then (q`2)^2>1^2 by A5,SQUARE_1:47;
        then
A28:    sqrt((q`2)^2)>1 by SQUARE_1:18,27;
        |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).|^2
        =((q`1)/sqrt(1+(q`1/(q`2))^2))^2+(q`2/sqrt(1+(q`1/(q`2))^2))^2
        by A20,A21,JGRAPH_3:1
          .=(q`1)^2/(sqrt(1+(q`1/(q`2))^2))^2+(q`2/sqrt(1+(q`1/(q`2))^2))^2
        by XCMPLX_1:76
          .=(q`1)^2/(sqrt(1+(q`1/(q`2))^2))^2
        +(q`2)^2/(sqrt(1+(q`1/(q`2))^2))^2 by XCMPLX_1:76
          .=(q`1)^2/(1+(q`1/q`2)^2)+(q`2)^2/(sqrt(1+(q`1/q`2)^2))^2
        by A22,SQUARE_1:def 2
          .=(q`1)^2/(1+(q`1/q`2)^2)+(q`2)^2/(1+(q`1/q`2)^2)
        by A22,SQUARE_1:def 2
          .=((q`1)^2+(q`2)^2)/(1+(q`1/q`2)^2) by XCMPLX_1:62
          .=((q`1)^2+(q`2)^2)/(1+(q`1)^2/(q`2)^2) by XCMPLX_1:76
          .=((q`1)^2+(q`2)^2)/((q`1)^2/(q`2)^2+(q`2)^2/(q`2)^2)
        by A24,XCMPLX_1:60
          .=((q`1)^2+(q`2)^2)/(((q`1)^2+(q`2)^2)/(q`2)^2)
        by XCMPLX_1:62
          .=(q`2)^2*(((q`1)^2+(q`2)^2)/((q`1)^2+(q`2)^2))
        by XCMPLX_1:81
          .=(q`2)^2*1 by A23,COMPLEX1:1,XCMPLX_1:60
          .=(q`2)^2;
        then |.(|[q`1/sqrt(1+(q`1/q`2)^2),q`2/sqrt(1+(q`1/q`2)^2)]|).|>1
        by A28,SQUARE_1:22;
        hence ex p2 being Point of TOP-REAL 2 st p2=y & |.p2.|>1 by A3,A4,A19;
      end;
    end;
    hence thesis by A1;
  end;
  let y be object;
  assume y in Cb;
  then consider p2 being Point of TOP-REAL 2 such that
A29: p2=y and
A30: |.p2.|>1 by A1;
  set q=p2;
  now per cases;
    case q=0.TOP-REAL 2;
      hence contradiction by A30,TOPRNS_1:23;
    end;
    case
A31:  q<>0.TOP-REAL 2 & (q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
      set px=|[q`1*sqrt(1+(q`2/q`1)^2),q`2*sqrt(1+(q`2/q`1)^2)]|;
A32:  px`1 = q`1*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
A33:  px`2 = q`2*sqrt(1+(q`2/q`1)^2) by EUCLID:52;
      1+(q`2/q`1)^2>0 by XREAL_1:34,63;
      then
A34:  sqrt(1+(q`2/q`1)^2)>0 by SQUARE_1:25;
A35:  1+(px`2/px`1)^2>0 by XREAL_1:34,63;
A36:  px`2/px`1=q`2/q`1 by A32,A33,A34,XCMPLX_1:91;
A37:  q`1=q`1*sqrt(1+(q`2/q`1)^2)/(sqrt(1+(q`2/q`1)^2))by A34,XCMPLX_1:89
        .=px`1/(sqrt(1+(q`2/q`1)^2)) by EUCLID:52;
A38:  q`2=q`2*sqrt(1+(q`2/q`1)^2)/(sqrt(1+(q`2/q`1)^2))by A34,XCMPLX_1:89
        .=px`2/(sqrt(1+(q`2/q`1)^2)) by EUCLID:52;
A39:  |.q.|^2=q`1^2+q`2^2 by JGRAPH_3:1;
A40:  |.q.|^2>1^2 by A30,SQUARE_1:16;
A41:  now
        assume that
A42:    px`1=0 and
A43:    px`2=0;
A44:    q`1*sqrt(1+(q`2/q`1)^2)=0 by A42,EUCLID:52;
A45:    q`2*sqrt(1+(q`2/q`1)^2)=0 by A43,EUCLID:52;
A46:    q`1=0 by A34,A44,XCMPLX_1:6;
        q`2=0 by A34,A45,XCMPLX_1:6;
        hence contradiction by A31,A46,EUCLID:53,54;
      end;
      q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 &
      q`2*sqrt(1+(q`2/q`1)^2) <= (-q`1)*sqrt(1+(q`2/q`1)^2)
      by A31,A34,XREAL_1:64;
      then
A47:  q`2<=q`1 & (-q`1)*sqrt(1+(q`2/q`1)^2) <= q`2*sqrt(1+(q`2/q`1) ^2)
      or px`2>=px`1 & px`2<=-px`1 by A32,A33,A34,XREAL_1:64;
      then px`2<=px`1 & -px`1<=px`2 or px`2>=px`1 & px`2<=-px`1
      by A32,A33,A34,XREAL_1:64;
      then
      A48:  Sq_Circ
.px=|[px`1/sqrt(1+(px`2/px`1)^2),px`2/sqrt(1+(px`2/px`1 )^2) ]|
      by A41,JGRAPH_2:3,JGRAPH_3:def 1;
A49:  px`1/sqrt(1+(px`2/px`1)^2)=q`1 by A32,A34,A36,XCMPLX_1:89;
A50:  px`2/sqrt(1+(px`2/px`1)^2)=q`2 by A33,A34,A36,XCMPLX_1:89;
A51:  dom Sq_Circ=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
      not px`1=0 by A32,A33,A34,A41,A47,XREAL_1:64;
      then
A52:  (px`1)^2>0 by SQUARE_1:12;
A53:  (px`2)^2>=0 by XREAL_1:63;
      (px`1)^2/(sqrt(1+(px`2/px`1)^2))^2+(px`2/sqrt(1+(px`2/px`1)^2)) ^2 > 1
      by A36,A37,A38,A39,A40,XCMPLX_1:76;
      then (px`1)^2/(sqrt(1+(px`2/px`1)^2))^2+(px`2)^2/(sqrt(1+(px`2/px`1)^2))
      ^2>1 by XCMPLX_1:76;
      then (px`1)^2/(1+(px`2/px`1)^2)+(px`2)^2/(sqrt(1+(px`2/px`1)^2))^2>1
      by A35,SQUARE_1:def 2;
      then (px`1)^2/(1+(px`2/px`1)^2)+(px`2)^2/(1+(px`2/px`1)^2)>1
      by A35,SQUARE_1:def 2;
      then ((px`1)^2/(1+(px`2/px`1)^2)
      +(px`2)^2/(1+(px`2/px`1)^2))*(1+(px`2/px`1)^2)>1 *(1+(px`2/px`1)^2)
      by A35,XREAL_1:68;
      then (px`1)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2)
      +(px`2)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2)>1 *(1+(px`2/px`1)^2);
      then (px`1)^2+(px`2)^2/(1+(px`2/px`1)^2)*(1+(px`2/px`1)^2)>1 *(1+(px`2/
      px `1)^2) by A35,XCMPLX_1:87;
      then
A54:  (px`1)^2+(px`2)^2>1 *(1+(px`2/px`1)^2) by A35,XCMPLX_1:87;
      1 *(1+(px`2/px`1)^2) =1+(px`2)^2/(px`1)^2 by XCMPLX_1:76;
      then (px`1)^2+(px`2)^2-1>1+(px`2)^2/(px`1)^2-1 by A54,XREAL_1:9;
      then ((px`1)^2+(px`2)^2-1)*(px`1)^2>((px`2)^2/(px`1)^2)*(px`1)^2
      by A52,XREAL_1:68;
      then
A55:  ((px`1)^2+((px`2)^2-1))*(px`1)^2>(px`2)^2 by A52,XCMPLX_1:87;
      (px`1)^2*(px`1)^2+((px`1)^2*(px`2)^2-(px`1)^2*1)-(px`2)^2
      = ((px`1)^2-1)*((px`1)^2+(px`2)^2);
      then (px`1)^2-1>0 or (px`1)^2+(px`2)^2<0 by A55,XREAL_1:50;
      then (px`1)^2-1+1>0+1 by A52,A53,XREAL_1:6;
      then px`1>1^2 or px`1< -1 by SQUARE_1:49;
      then px in Kb by A1;
      hence ex x being set st x in dom Sq_Circ & x in Kb & y=Sq_Circ.x
      by A29,A48,A49,A50,A51,EUCLID:53;
    end;
    case
A56:  q<>0.TOP-REAL 2 & not(q`2<=q`1 & -q`1<=q`2 or q`2>=q`1 & q`2<=-q`1);
      set px=|[q`1*sqrt(1+(q`1/q`2)^2),q`2*sqrt(1+(q`1/q`2)^2)]|;
A57:  q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 & q`1<=-q`2 by A56,JGRAPH_2:13;
A58:  px`2 = q`2*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
A59:  px`1 = q`1*sqrt(1+(q`1/q`2)^2) by EUCLID:52;
      1+(q`1/q`2)^2>0 by XREAL_1:34,63;
      then
A60:  sqrt(1+(q`1/q`2)^2)>0 by SQUARE_1:25;
A61:  1+(px`1/px`2)^2>0 by XREAL_1:34,63;
A62:  px`1/px`2=q`1/q`2 by A58,A59,A60,XCMPLX_1:91;
A63:  q`2=q`2*sqrt(1+(q`1/q`2)^2)/(sqrt(1+(q`1/q`2)^2))by A60,XCMPLX_1:89
        .=px`2/(sqrt(1+(q`1/q`2)^2)) by EUCLID:52;
A64:  q`1=q`1*sqrt(1+(q`1/q`2)^2)/(sqrt(1+(q`1/q`2)^2))by A60,XCMPLX_1:89
        .=px`1/(sqrt(1+(q`1/q`2)^2)) by EUCLID:52;
A65:  |.q.|^2=q`2^2+q`1^2 by JGRAPH_3:1;
A66:  |.q.|^2>1^2 by A30,SQUARE_1:16;
A67:  now
        assume that
A68:    px`2=0 and
A69:    px`1=0;
A70:    q`2*sqrt(1+(q`1/q`2)^2)=0 by A68,EUCLID:52;
        q`1*sqrt(1+(q`1/q`2)^2)=0 by A69,EUCLID:52;
        then q`1=0 by A60,XCMPLX_1:6;
        hence contradiction by A56,A70;
      end;
      q`1<=q`2 & -q`2<=q`1 or q`1>=q`2 &
      q`1*sqrt(1+(q`1/q`2)^2) <= (-q`2)*sqrt(1+(q`1/q`2)^2)
      by A57,A60,XREAL_1:64;
      then
A71:  q`1<=q`2 & (-q`2)*sqrt(1+(q`1/q`2)^2) <= q`1*sqrt(1+(q`1/q`2) ^2)
      or px`1>=px`2 & px`1<=-px`2 by A58,A59,A60,XREAL_1:64;
      then px`1<=px`2 & -px`2<=px`1 or px`1>=px`2 & px`1<=-px`2
      by A58,A59,A60,XREAL_1:64;
      then
      A72:  Sq_Circ
.px=|[px`1/sqrt(1+(px`1/px`2)^2),px`2/sqrt(1+(px`1/px`2 )^2) ]|
      by A67,JGRAPH_2:3,JGRAPH_3:4;
A73:  px`2/sqrt(1+(px`1/px`2)^2)=q`2 by A58,A60,A62,XCMPLX_1:89;
A74:  px`1/sqrt(1+(px`1/px`2)^2)=q`1 by A59,A60,A62,XCMPLX_1:89;
A75:  dom Sq_Circ=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
      not px`2=0 by A58,A59,A60,A67,A71,XREAL_1:64;
      then
A76:  (px`2)^2>0 by SQUARE_1:12;
A77:  (px`1)^2>=0 by XREAL_1:63;
      (px`2)^2/(sqrt(1+(px`1/px`2)^2))^2+(px`1/sqrt(1+(px`1/px`2)^2)) ^2 > 1
      by A62,A63,A64,A65,A66,XCMPLX_1:76;
      then (px`2)^2/(sqrt(1+(px`1/px`2)^2))^2+(px`1)^2/(sqrt(1+(px`1/px`2)^2))
      ^2>1 by XCMPLX_1:76;
      then (px`2)^2/(1+(px`1/px`2)^2)+(px`1)^2/(sqrt(1+(px`1/px`2)^2))^2>1
      by A61,SQUARE_1:def 2;
      then (px`2)^2/(1+(px`1/px`2)^2)+(px`1)^2/(1+(px`1/px`2)^2)>1
      by A61,SQUARE_1:def 2;
      then ((px`2)^2/(1+(px`1/px`2)^2)
      +(px`1)^2/(1+(px`1/px`2)^2))*(1+(px`1/px`2)^2)>1 *(1+(px`1/px`2)^2)
      by A61,XREAL_1:68;
      then (px`2)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2)
      +(px`1)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2)>1 *(1+(px`1/px`2)^2);
      then (px`2)^2+(px`1)^2/(1+(px`1/px`2)^2)*(1+(px`1/px`2)^2)>1 *(1+(px`1/
      px `2)^2) by A61,XCMPLX_1:87;
      then
A78:  (px`2)^2+(px`1)^2>1 *(1+(px`1/px`2)^2) by A61,XCMPLX_1:87;
      1 *(1+(px`1/px`2)^2) =1+(px`1)^2/(px`2)^2 by XCMPLX_1:76;
      then (px`2)^2+(px`1)^2-1>1+(px`1)^2/(px`2)^2-1 by A78,XREAL_1:9;
      then ((px`2)^2+(px`1)^2-1)*(px`2)^2>((px`1)^2/(px`2)^2)*(px`2)^2
      by A76,XREAL_1:68;
      then
A79:  ((px`2)^2+((px`1)^2-1))*(px`2)^2>(px`1)^2 by A76,XCMPLX_1:87;
      (px`2)^2*(px`2)^2+((px`2)^2*(px`1)^2-(px`2)^2*1)-(px`1)^2
      = ((px`2)^2-1)*((px`2)^2+(px`1)^2);
      then (px`2)^2-1>0 or (px`1)^2+(px`2)^2<0 by A79,XREAL_1:50;
      then (px`2)^2-1+1>0+1 by A76,A77,XREAL_1:6;
      then px`2>1^2 or px`2< -1 by SQUARE_1:49;
      then px in Kb by A1;
      hence ex x being set st x in dom Sq_Circ & x in Kb & y=Sq_Circ.x
      by A29,A72,A73,A74,A75,EUCLID:53;
    end;
  end;
  hence thesis by FUNCT_1:def 6;
end;
