reserve i, i1, i2, j, j1, j2, k, m, n, t for Nat,
  D for non empty Subset of TOP-REAL 2,
  E for compact non vertical non horizontal Subset of TOP-REAL 2,
  C for compact connected non vertical non horizontal Subset of TOP-REAL 2,
  G for Go-board,
  p, q, x for Point of TOP-REAL 2,
  r, s for Real;

theorem Th26:
  i <= len G implies cell(G,i,0) is not bounded
proof
  assume
A1: i <= len G;
  per cases by A1,NAT_1:14,XXREAL_0:1;
  suppose
    i = 0;
    then
A2: cell(G,i,0) = { |[r,s]| where r, s is Real:
     r <= G*(1,1)`1 & s <= G*(1,1)`2 } by GOBRD11:24;
    not ex r being Real
     st for q being Point of TOP-REAL 2 st q in cell(G,i,0) holds |.q.| < r
    proof
      let r be Real;
      take q = |[min(-r,G*(1,1)`1),min(-r,G*(1,1)`2)]|;
A3:   |.q`1.|<=|.q.| by JGRAPH_1:33;
      min(-r,G*(1,1)`1) <= G*(1,1)`1 & min(-r,G*(1,1)`2) <= G*(1,1)`2 by
XXREAL_0:17;
      hence q in cell(G,i,0) by A2;
      per cases;
      suppose
        r <= 0;
        hence thesis;
      end;
      suppose
A4:     r > 0;
        q`1 = min(-r,G*(1,1)`1) by EUCLID:52;
        then
A5:     |.-r.| <= |.q`1.| by A4,TOPREAL6:3,XXREAL_0:17;
        --r > 0 by A4;
        then -r < 0;
        then --r <= |.q`1.| by A5,ABSVALUE:def 1;
        hence thesis by A3,XXREAL_0:2;
      end;
    end;
    hence thesis by JORDAN2C:34;
  end;
  suppose
A6: i >= 1 & i < len G;
    then
A7: cell(G,i,0) = { |[r,s]| where r is Real, s is Real:
     G*(i,1)`1 <= r & r <= G*(i+1,1)`1 & s <= G*(1,1)`2 } by GOBRD11:30;
    not ex r being Real
      st for q being Point of TOP-REAL 2 st q in cell(G,i,0) holds |.q.| < r
    proof
      let r be Real;
      take q = |[G*(i,1)`1,min(-r,G*(1,1)`2)]|;
A8:   min(-r,G*(1,1)`2) <= G*(1,1)`2 by XXREAL_0:17;
      width G <> 0 by MATRIX_0:def 10;
      then
A9:   1 <= width G by NAT_1:14;
      i < i+1 & i+1 <= len G by A6,NAT_1:13;
      then G*(i,1)`1 <= G*(i+1,1)`1 by A6,A9,GOBOARD5:3;
      hence q in cell(G,i,0) by A7,A8;
A10:  |.q`2.|<=|.q.| by JGRAPH_1:33;
      per cases;
      suppose
        r <= 0;
        hence thesis;
      end;
      suppose
A11:    r > 0;
        q`2 = min(-r,G*(1,1)`2) by EUCLID:52;
        then
A12:    |.-r.| <= |.q`2.| by A11,TOPREAL6:3,XXREAL_0:17;
        --r > 0 by A11;
        then -r < 0;
        then --r <= |.q`2.| by A12,ABSVALUE:def 1;
        hence thesis by A10,XXREAL_0:2;
      end;
    end;
    hence thesis by JORDAN2C:34;
  end;
  suppose
    i = len G;
    then
A13: cell(G,i,0) = { |[r,s]| where r is Real, s is Real :
      G*(len G,1)`1 <= r & s <= G*(1,1)`2 } by GOBRD11:27;
    not ex r being Real
    st for q being Point of TOP-REAL 2 st q in cell(G,i,0) holds |.q.| < r
    proof
      let r be Real;
      take q = |[max(r,G*(len G,1)`1),G*(1,1)`2]|;
A14:  |.q`1.|<=|.q.| by JGRAPH_1:33;
      G*(len G,1)`1 <= max(r,G*(len G,1)`1) by XXREAL_0:25;
      hence q in cell(G,i,0) by A13;
      per cases;
      suppose
        r <= 0;
        hence thesis;
      end;
      suppose
A15:    r > 0;
        q`1 = max(r,G*(len G,1)`1) by EUCLID:52;
        then r <= q`1 by XXREAL_0:25;
        then r <= |.q`1.| by A15,ABSVALUE:def 1;
        hence thesis by A14,XXREAL_0:2;
      end;
    end;
    hence thesis by JORDAN2C:34;
  end;
end;
