reserve i,j,k,n for Nat;

theorem
  for f being non constant standard special_circular_sequence holds f is
  clockwise_oriented iff Rotate(f,E-max L~f)/.2 in E-most L~f
proof
  let f be non constant standard special_circular_sequence;
  set r = Rotate(f,E-max L~f);
  set j = i_n_e r;
  set i = len GoB r;
A1: 1+1 <= len r & r is_sequence_on GoB r by GOBOARD5:def 5,TOPREAL8:3;
A2: E-max L~f in rng f by SPRECT_2:46;
  then
A3: r/.1 = E-max L~f by FINSEQ_6:92;
A4: 2 <= len f by TOPREAL8:3;
  thus f is clockwise_oriented implies r/.2 in E-most L~f
  proof
    set k = (E-max L~f)..f;
    k < len f by SPRECT_5:16;
    then
A5: k+1 <= len f by NAT_1:13;
    1 <= k+1 by NAT_1:11;
    then
A6: k+1 in dom f by A5,FINSEQ_3:25;
    then f/.(k+1) = f.(k+1) by PARTFUN1:def 6;
    then
A7: f/.(k+1) in rng f by A6,FUNCT_1:3;
A8: rng f c= L~f by A4,SPPOL_2:18;
A9: f/.k = E-max L~f by A2,FINSEQ_5:38;
    k <= k+1 by NAT_1:13;
    then
A10: f/.(k+1) = r/.(k+1+1 -' k) by A2,A5,FINSEQ_6:175
      .= r/.(k+(1+1) -' k)
      .= r/.2 by NAT_D:34;
    f is_sequence_on GoB f by GOBOARD5:def 5;
    then
A11: f is_sequence_on GoB r by REVROT_1:28;
    assume f is clockwise_oriented;
    then consider i,j being Nat such that
A12: [i,j+1] in Indices GoB r and
A13: [i,j] in Indices GoB r and
A14: f/.k = (GoB r)*(i,j+1) and
A15: f/.(k+1) = (GoB r)*(i,j) by A2,A5,A9,A11,Th23,FINSEQ_4:21;
A16: 1 <= j & j <= width GoB r by A13,MATRIX_0:32;
A17: 1 <= j+1 & j+1 <= width GoB r by A12,MATRIX_0:32;
A18: 1 <= i & i <= len GoB r by A12,MATRIX_0:32;
    1 <= i & i <= len GoB r by A12,MATRIX_0:32;
    then (f/.(k+1))`1 = (GoB r)*(i,1)`1 by A15,A16,GOBOARD5:2
      .= (f/.k)`1 by A14,A18,A17,GOBOARD5:2
      .= E-bound L~f by A9,EUCLID:52;
    hence thesis by A10,A7,A8,SPRECT_2:13;
  end;
  assume
A19: r/.2 in E-most L~f;
  len r > 2 by TOPREAL8:3;
  then
A20: r is_sequence_on GoB r & 1+1 in dom r by FINSEQ_3:25,GOBOARD5:def 5;
  then consider i2,j2 being Nat such that
A21: [i2,j2] in Indices GoB r and
A22: r/.(1+1) = (GoB r)*(i2,j2) by GOBOARD1:def 9;
A23: j2 <= width GoB r by A21,MATRIX_0:32;
A24: [i,j] in Indices GoB r by JORDAN5D:def 4;
  then
A25: 1 <= j by MATRIX_0:32;
  then
A26: [i,j-'1+1] in Indices GoB r by A24,XREAL_1:235;
A27: L~r = L~f by REVROT_1:33;
  then
A28: (GoB r)*(i,j) = r/.1 by A3,JORDAN5D:def 4;
  then
A29: r/.1 = (GoB r)*(i,j-'1+1) by A25,XREAL_1:235;
  (GoB r)*(i,j) in E-most L~r by A27,A3,A28,PSCOMP_1:50;
  then (GoB r)*(i,j)`1 = (E-min L~r)`1 by PSCOMP_1:47;
  then
A30: (GoB r)*(i2,j2)`1 = (GoB r)*(i,j)`1 by A27,A19,A22,PSCOMP_1:47;
  then
A31: i2 = i by A24,A21,JORDAN1G:7;
A32: 1+1 <= len r by TOPREAL8:3;
  then
A33: Int left_cell(r,1) c= LeftComp r by GOBOARD9:21;
  Int left_cell(r,1) <> {} by A32,GOBOARD9:15;
  then consider p being object such that
A34: p in Int left_cell(r,1) by XBOOLE_0:def 1;
  reconsider p as Point of TOP-REAL2 by A34;
A35: LeftComp r is_a_component_of (L~r)` & UBD L~r is_a_component_of (L~r)`
  by GOBOARD9:def 1,JORDAN2C:124;
A36: 1 <= j2 by A21,MATRIX_0:32;
A37: j <= width GoB r by A24,MATRIX_0:32;
  rng r = rng f by FINSEQ_6:90,SPRECT_2:46;
  then 1 in dom r by FINSEQ_3:31,SPRECT_2:46;
  then |.i2-i2.|+|.j-j2.| = 1 by A24,A28,A20,A21,A22,A31,GOBOARD1:def 9;
  then
A38: 0+|.j-j2.| = 1 by ABSVALUE:2;
A39: 1 <= i by A24,MATRIX_0:32;
  (GoB r)*(i,j)`2 >= (GoB r)*(i2,j2)`2 by A3,A28,A19,A22,PSCOMP_1:47;
  then j - j2 >= 0 by A39,A25,A31,A23,GOBOARD5:4,XREAL_1:48;
  then
A40: j - j2 = 1 by A38,ABSVALUE:def 1;
  then j2 = j-1;
  then
A41: j2 = j-'1 by A25,XREAL_1:233;
  then [i,j-'1] in Indices GoB r & r/.(1+1) = (GoB r)*(i,j-'1) by A24,A21,A22
,A30,JORDAN1G:7;
  then left_cell(r,1,GoB r) = cell(GoB r,i,j-'1) by A1,A26,A29,GOBRD13:27;
  then
A42: left_cell(r,1) = cell(GoB r,i,j-'1) by A32,JORDAN1H:21;
  j-1 < j-0 by XREAL_1:15;
  then j-'1 < width GoB r by A37,A40,A41,XXREAL_0:2;
  then Int left_cell(r,1) = { |[t,s]| where t,s is Real:
(GoB r)*(i,1)`1 < t
  & (GoB r)*(1,j-'1)`2 < s & s < (GoB r)*(1,j-'1+1)`2 } by A36,A41,A42,
GOBOARD6:23;
  then consider t,s being Real such that
A43: p = |[t,s]| and
A44: (GoB r)*(i,1)`1 < t and
  (GoB r)*(1,j-'1)`2 < s and
  s < (GoB r)*(1,j-'1+1)`2 by A34;
  now
    assume east_halfline p meets L~r;
    then (east_halfline p) /\ L~r <> {} by XBOOLE_0:def 7;
    then consider a being object such that
A45: a in (east_halfline p) /\ L~r by XBOOLE_0:def 1;
A46: a in L~r by A45,XBOOLE_0:def 4;
A47: a in (east_halfline p) by A45,XBOOLE_0:def 4;
    reconsider a as Point of TOP-REAL2 by A45;
    a`1 >= p`1 by A47,TOPREAL1:def 11;
    then
A48: a`1 >= t by A43,EUCLID:52;
    (GoB r)*(i,1)`1 = (GoB r)*(i,j)`1 by A39,A25,A37,GOBOARD5:2;
    then a`1 > (GoB r)*(i,j)`1 by A44,A48,XXREAL_0:2;
    then a`1 > E-bound L~r by A27,A3,A28,EUCLID:52;
    hence contradiction by A46,PSCOMP_1:24;
  end;
  then
A49: east_halfline p c= UBD L~r by JORDAN2C:127;
  p in east_halfline p by TOPREAL1:38;
  then LeftComp r meets UBD L~r by A33,A34,A49,XBOOLE_0:3;
  then r is clockwise_oriented by A35,GOBOARD9:1,JORDAN1H:41;
  hence thesis by JORDAN1H:40;
end;
