reserve C for Simple_closed_curve,
  i for Nat;
reserve R for non empty Subset of TOP-REAL 2,
  j, k, m, n for Nat;

theorem Th26:
  i <= j implies (LMP L~Cage(C,i))`2 <= (LMP L~Cage(C,j))`2
proof
  set w = (E-bound C + W-bound C) / 2, ui = LMP L~Cage(C,i), uj = LMP L~Cage(C
  ,j);
  assume i <= j;
  then
A1: LeftComp(Cage(C,i)) c= LeftComp(Cage(C,j)) by JORDAN1H:47;
A2: W-bound L~Cage(C,j) + E-bound L~Cage(C,j) = W-bound C + E-bound C by
JORDAN1G:33;
  then
A3: uj`2 = lower_bound (proj2.:(L~Cage(C,j) /\ Vertical_Line w)) by EUCLID:52;
  assume (LMP L~Cage(C,i))`2 > (LMP L~Cage(C,j))`2;
  then
A4: ui`2 - uj`2 > 0 by XREAL_1:50;
A5: W-bound L~Cage(C,i) + E-bound L~Cage(C,i) = W-bound C + E-bound C by
JORDAN1G:33;
  then
A6: ui`2 = lower_bound (proj2.:(L~Cage(C,i) /\ Vertical_Line w)) by EUCLID:52;
A7: proj2.:(L~Cage(C,i) /\ Vertical_Line w) is non empty bounded_below by A5,
JORDAN21:12,13;
  proj2.:(L~Cage(C,j) /\ Vertical_Line w) is non empty bounded_below by A2,
JORDAN21:12,13;
  then consider r being Real such that
A8: r in proj2.:(L~Cage(C,j) /\ Vertical_Line w) and
A9: r < lower_bound (proj2.:(L~Cage(C,j) /\ Vertical_Line w)) + (ui`2 - uj`2)
  by A4,SEQ_4:def 2;
  consider x being Point of TOP-REAL 2 such that
A10: x in L~Cage(C,j) /\ Vertical_Line w and
A11: proj2.x = r by A8,Lm1;
A12: x`2 = r by A11,PSCOMP_1:def 6;
  south_halfline x misses L~Cage(C,i)
  proof
A13: x in Vertical_Line w by A10,XBOOLE_0:def 4;
    assume south_halfline x meets L~Cage(C,i);
    then consider y being object such that
A14: y in south_halfline x and
A15: y in L~Cage(C,i) by XBOOLE_0:3;
    reconsider y as Point of TOP-REAL 2 by A15;
    y`1 = x`1 by A14,TOPREAL1:def 12
      .= w by A13,JORDAN6:31;
    then y in Vertical_Line w;
    then
A16: y in L~Cage(C,i) /\ Vertical_Line w by A15,XBOOLE_0:def 4;
    proj2.y = y`2 by PSCOMP_1:def 6;
    then y`2 in proj2.:(L~Cage(C,i) /\ Vertical_Line w) by A16,FUNCT_2:35;
    then
A17: y`2 >= ui`2 by A6,A7,SEQ_4:def 2;
    y`2 <= x`2 by A14,TOPREAL1:def 12;
    hence contradiction by A3,A9,A12,A17,XXREAL_0:2;
  end;
  then
A18: south_halfline x c= UBD L~Cage(C,i) by JORDAN2C:128;
  x in south_halfline x by TOPREAL1:38;
  then x in UBD L~Cage(C,i) by A18;
  then
A19: x in LeftComp Cage(C,i) by GOBRD14:36;
  x in L~Cage(C,j) by A10,XBOOLE_0:def 4;
  then LeftComp Cage(C,j) meets L~Cage(C,j) by A1,A19,XBOOLE_0:3;
  hence thesis by SPRECT_3:26;
end;
