reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem Th26:
  for P being Subset of R^1,a,b being Real st P = { s: a<s
  & s<b } holds P is open
proof
  let P be Subset of R^1,a,b be Real;
  { w1:a<w1} c= the carrier of R^1
  proof
    let x be object;
    assume x in { w1:a<w1};
    then consider  r1 be Real such that
A1:   x= r1 & a<r1;
     r1 in REAL by XREAL_0:def 1;
    hence thesis by TOPMETR:17,A1;
  end;
  then reconsider P1={w1:a<w1} as Subset of R^1;
  {w2:w2<b} c= the carrier of R^1
  proof
    let x be object;
    assume x in {w2:w2<b};
    then consider r2 be Real such that
A2:   x= r2 & r2<b;
     r2 in REAL by XREAL_0:def 1;
    hence thesis by TOPMETR:17,A2;
  end;
  then reconsider P2={w2:w2<b} as Subset of R^1;
  assume
A3: P = { s: a<s & s<b };
A4: P = { w1: a<w1} /\ {w2: w2<b}
  proof
A5: { w1 :a<w1} /\ {w2:w2<b } c= P
    proof
      let x be object;
      assume
A6:   x in { w1 :a<w1} /\ {w2:w2<b };
      then x in {w2:w2<b } by XBOOLE_0:def 4;
      then
A7:   ex r2 be Real st x=r2 & r2<b;
      x in { w1 :a<w1} by A6,XBOOLE_0:def 4;
      then ex r1 be Real st x=r1 & a<r1;
      hence thesis by A3,A7;
    end;
    P c= {w1: a<w1} /\ {w2: w2<b }
    proof
      let x be object;
      assume x in P;
      then
A8:   ex s st s=x & a<s & s<b by A3;
      then
A9:   x in {w2:w2<b };
      x in { w1 :a<w1} by A8;
      hence thesis by A9,XBOOLE_0:def 4;
    end;
    hence thesis by A5,XBOOLE_0:def 10;
  end;
  P1 is open & P2 is open by Th24,Th25;
  hence thesis by A4,TOPS_1:11;
end;
