reserve i,j,k,n for Nat,
  D for non empty set,
  f, g for FinSequence of D;
reserve G for Go-board,
  f, g for FinSequence of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  r, s for Real,
  x for set;

theorem Th26:
  f is_sequence_on G & f is special & L~g c= L~f & 1 <= k & k+1 <=
len f implies for A being Subset of TOP-REAL 2 st A = right_cell(f,k,G)\L~g or
  A = left_cell(f,k,G)\L~g holds A is connected
proof
  assume that
A1: f is_sequence_on G and
A2: f is special and
A3: L~g c= L~f and
A4: 1 <= k & k+1 <= len f;
  let A be Subset of TOP-REAL 2 such that
A5: A = right_cell(f,k,G)\L~g or A = left_cell(f,k,G)\L~g;
  per cases by A5;
  suppose
A6: A = right_cell(f,k,G)\L~g;
    Int right_cell(f,k,G) misses L~f by A1,A2,A4,Th15;
    then Int right_cell(f,k,G) misses L~g by A3,XBOOLE_1:63;
    then
A7: Int right_cell(f,k,G) c= (L~g)` by SUBSET_1:23;
    A c= right_cell(f,k,G) by A6,XBOOLE_1:36;
    then
A8: A c= Cl Int right_cell(f,k,G) by A1,A4,Th11;
A9: A = right_cell(f,k,G) /\ (L~g)` by A6,SUBSET_1:13;
    Int right_cell(f,k,G) is convex & Int right_cell(f,k,G) c=
    right_cell(f,k,G) by A1,A4,Th10,TOPS_1:16;
    hence thesis by A9,A7,A8,CONNSP_1:18,XBOOLE_1:19;
  end;
  suppose
A10: A = left_cell(f,k,G)\L~g;
    Int left_cell(f,k,G) misses L~f by A1,A2,A4,Th15;
    then Int left_cell(f,k,G) misses L~g by A3,XBOOLE_1:63;
    then
A11: Int left_cell(f,k,G) c= (L~g)` by SUBSET_1:23;
    A c= left_cell(f,k,G) by A10,XBOOLE_1:36;
    then
A12: A c= Cl Int left_cell(f,k,G) by A1,A4,Th11;
A13: A = left_cell(f,k,G) /\ (L~g)` by A10,SUBSET_1:13;
    Int left_cell(f,k,G) is convex & Int left_cell(f,k,G) c= left_cell
    (f,k,G) by A1,A4,Th10,TOPS_1:16;
    hence thesis by A13,A11,A12,CONNSP_1:18,XBOOLE_1:19;
  end;
end;
