reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th26:
  for i st i in Seg n holds LaplaceExpC(M,i) = LaplaceExpL(M@,i)
proof
  let i such that
A1: i in Seg n;
  set LL=LaplaceExpL(M@,i);
  set LC=LaplaceExpC(M,i);
  reconsider I=i as Element of NAT by ORDINAL1:def 12;
A2: len LL=n by Def7;
A3: len LC=n by Def8;
  now
    let k be Nat such that
A4: 1 <=k and
A5: k <= n;
A6: k in Seg n by A4,A5;
    dom LC=Seg n by A3,FINSEQ_1:def 3;
    then
A7: LC.k=M*(k,I)*Cofactor(M,k,I) by A6,Def8;
    Indices M=[:Seg n,Seg n:] by MATRIX_0:24;
    then
A8: [k,i] in Indices M by A1,A6,ZFMISC_1:87;
    dom LL=Seg n by A2,FINSEQ_1:def 3;
    then
A9: LL.k=M@*(I,k)*Cofactor(M@,I,k) by A6,Def7;
    Cofactor(M,k,I)=Cofactor(M@,I,k) by A1,A6,Th24;
    hence LC.k=LL.k by A8,A7,A9,MATRIX_0:def 6;
  end;
  hence thesis by A3,A2;
end;
