
theorem
  for L being distributive Lattice,
      a, b being Element of L holds
    PrimeFilters L.(a "/\" b) = PrimeFilters L.a /\ PrimeFilters L.b
  proof
    let L be distributive Lattice,
        a, b be Element of L;
A1: PrimeFilters L.(a "/\" b) c= PrimeFilters L.a /\ PrimeFilters L.b
    proof
      let x be object;
      set c = a "/\" b;
      assume x in PrimeFilters L.c;
      then consider F0 being Filter of L such that
A2:   x = F0 and
A3:   F0 is prime and
A4:   c in F0 by Th17;
A5:   a in F0 by A4,FILTER_0:8;
A6:   b in F0 by A4,FILTER_0:8;
A7:   F0 in PrimeFilters L.a by A3,A5,Th17;
      F0 in PrimeFilters L.b by A3,A6,Th17;
      hence thesis by A2,A7,XBOOLE_0:def 4;
    end;
    PrimeFilters L.a /\ PrimeFilters L.b c= PrimeFilters L.(a "/\" b)
    proof
      let x be object;
      assume
A8:   x in PrimeFilters L.a /\ PrimeFilters L.b; then
A9:   x in PrimeFilters L.a by XBOOLE_0:def 4;
A10:  x in PrimeFilters L.b by A8,XBOOLE_0:def 4;
A11:  ex F0 being Filter of L st x = F0 & F0 is prime & a in F0 by A9,Th17;
      ex F0 being Filter of L st x = F0 & F0 is prime & b in F0 by A10,Th17;
      then consider F0 being Filter of L such that
A12:  x = F0 and
A13:  F0 is prime and
A14:  a in F0 and
A15:  b in F0 by A11;
      a "/\" b in F0 by A14,A15,FILTER_0:8;
      hence thesis by A12,A13,Th17;
    end;
    hence thesis by A1;
  end;
