reserve

  k,n,m,i,j for Element of NAT,
  K for Field;
reserve L for non empty addLoopStr;
reserve G for non empty multLoopStr;

theorem Th26:
  for i,n being Nat st 1<=i & i<=n holds (1.(K,n)).i=Base_FinSeq(K ,n,i)
proof
  let i,n be Nat;
  assume
A1: 1<=i & i<=n;
  then 1<=n by XXREAL_0:2;
  then [i,1] in Indices (1.(K,n)) by A1,MATRIX_0:31;
  then consider q being FinSequence of K such that
A2: q = (1.(K,n)).i and
  (1.(K,n))*(i,1) = q.1 by MATRIX_0:def 5;
  len (1.(K,n))=n by MATRIX_0:24;
  then i in dom (1.(K,n)) by A1,FINSEQ_3:25;
  then q in rng (1.(K,n)) by A2,FUNCT_1:def 3;
  then
A3: len q=n by MATRIX_0:def 2;
A4: for j be Nat st 1<=j & j<=n holds q.j=(Base_FinSeq(K,n,i)).j
  proof
    let j be Nat;
    assume
A5: 1<=j & j<=n;
    then
A6: [i,j] in Indices (1.(K,n)) by A1,MATRIX_0:31;
    then
A7: ex q0 being FinSequence of K st q0 = (1.(K,n)).i & (1.(K, n))*(i,j) =
    q0.j by MATRIX_0:def 5;
    per cases;
    suppose
A8:   i=j;
      then (1.(K,n))*(i,i) = 1_(K) by A6,MATRIX_1:def 3;
      hence thesis by A1,A2,A7,A8,Th24;
    end;
    suppose
A9:   i<>j;
      then q.j=0.K by A2,A6,A7,MATRIX_1:def 3;
      hence thesis by A5,A9,Th25;
    end;
  end;
  len Base_FinSeq(K,n,i)=n by Th23;
  hence thesis by A2,A3,A4,FINSEQ_1:14;
end;
