reserve X for non empty set,
  Y for set,
  S for SigmaField of X,
  M for sigma_Measure of S,
  f,g for PartFunc of X,COMPLEX,
  r for Real,
  k for Real,
  n for Nat,
  E for Element of S;

theorem
  for f be with_the_same_dom Functional_Sequence of X,COMPLEX, E be
  Element of S st dom(f.0) = E & (for n be Nat holds f.n
is E-measurable) & (for x be Element of X st x in E holds f#x is convergent)
  holds lim f is E-measurable
proof
  let f be with_the_same_dom Functional_Sequence of X,COMPLEX, E be Element of
  S;
  assume that
A1: dom (f.0) = E and
A2: for n be Nat holds f.n is E-measurable and
A3: for x be Element of X st x in E holds f#x is convergent;
A4: lim Im f = R_EAL Im lim f by A1,A3,Th25;
A5: now
    let x be Element of X;
    assume
A6: x in E;
    then f#x is convergent by A3;
    then Im(f#x) is convergent;
    hence (Im f)#x is convergent by A1,A6,Th23;
  end;
A7: now
    let n be Nat;
    f.n is E-measurable by A2;
    then Im(f.n) is E-measurable by MESFUN6C:def 1;
    hence (Im f).n is E-measurable by Th24;
  end;
  dom((Im f).0) = E by A1,Def12;
  then lim Im f is E-measurable by A7,A5,Th21;
  then
A8: Im lim f is E-measurable by A4,MESFUNC6:def 1;
A9: now
    let x be Element of X;
    assume
A10: x in E;
    then f#x is convergent by A3;
    then Re(f#x) is convergent;
    hence (Re f)#x is convergent by A1,A10,Th23;
  end;
A11: now
    let n be Nat;
    f.n is E-measurable by A2;
    then Re(f.n) is E-measurable by MESFUN6C:def 1;
    hence (Re f).n is E-measurable by Th24;
  end;
A12: lim Re f = R_EAL Re lim f by A1,A3,Th25;
  dom((Re f).0) = E by A1,Def11;
  then lim Re f is E-measurable by A11,A9,Th21;
  then Re lim f is E-measurable by A12,MESFUNC6:def 1;
  hence thesis by A8,MESFUN6C:def 1;
end;
