reserve X for non empty set;
reserve e for set;
reserve x for Element of X;
reserve f,g for PartFunc of X,ExtREAL;
reserve S for SigmaField of X;
reserve F for Function of RAT,S;
reserve p,q for Rational;
reserve r for Real;
reserve n,m for Nat;
reserve A,B for Element of S;

theorem
  f is A-measurable & A c= dom f implies max-(f) is A-measurable
proof
  assume
A1: f is A-measurable & A c= dom f;
 for r be Real holds A /\ less_dom(max-(f), r) in S
  proof
    let r be Real;
    reconsider r as Real;
 now per cases;
      suppose
A2:     0 < r;
     (-1)(#)f is A-measurable by A1,MESFUNC1:37;
then A3:     -f is A-measurable by Th9;
     for x being object st x in less_dom(max-(f), r) holds
        x in less_dom(-f, r)
        proof
          let x be object;
          assume
A4:       x in less_dom(max-(f), r);
then A5:       x in dom max-(f) by MESFUNC1:def 11;
A6:      max-(f).x <  r by A4,MESFUNC1:def 11;
          reconsider x as Element of X by A4;
A7:      max(-(f.x),0.) <  r by A5,A6,Def3;
then A8:      -(f.x) <=  r by XXREAL_0:30;
      -(f.x) <>  r
          proof
            assume
A9:        -(f.x) =  r;
then         max(-(f.x),0.) = 0. by A7,XXREAL_0:16;
            hence contradiction by A7,A9,XXREAL_0:def 10;
          end;
then A10:      -(f.x) <  r by A8,XXREAL_0:1;
      x in dom f by A5,Def3;
then A11:      x in dom -f by MESFUNC1:def 7;
then       (-f).x = -(f.x) by MESFUNC1:def 7;
          hence thesis by A10,A11,MESFUNC1:def 11;
        end;
then A12:    less_dom(max-(f), r) c= less_dom(-f, r);
    for x being object st x in less_dom(-f, r) holds
        x in less_dom(max-(f), r)
        proof
          let x be object;
          assume
A13:      x in less_dom(-f, r);
then A14:      x in dom -f by MESFUNC1:def 11;
A15:      (-f).x <  r by A13,MESFUNC1:def 11;
          reconsider x as Element of X by A13;
      x in dom f by A14,MESFUNC1:def 7;
then A16:      x in dom (max-(f)) by Def3;
      now per cases;
            suppose
          0. <= -(f.x);
then           max(-(f.x),0.) = -(f.x) by XXREAL_0:def 10;
then           max-(f).x = -(f.x) by A16,Def3
                .= (-f).x by A14,MESFUNC1:def 7;
              hence thesis by A15,A16,MESFUNC1:def 11;
            end;
            suppose
          not 0. <= -(f.x);
then           max(-(f.x),0.) = 0. by XXREAL_0:def 10;
then           max-(f).x = 0. by A16,Def3;
              hence thesis by A2,A16,MESFUNC1:def 11;
            end;
          end;
          hence thesis;
        end;
then
    less_dom(-f, r) c= less_dom(max-(f), r);
then     less_dom(max-(f), r) = less_dom(-f, r) by A12;
        hence thesis by A3;
      end;
      suppose
A17:    r <= 0;
    for x being Element of X holds not x in less_dom(max-(f), r)
        proof
          let x be Element of X;
          assume
A18:      x in less_dom(max-(f), r);
then A19:      x in dom(max-(f)) by MESFUNC1:def 11;
A20:      max-(f).x <  r by A18,MESFUNC1:def 11;
      max-(f).x = max(-(f.x),0.) by A19,Def3;
          hence contradiction by A17,A20,XXREAL_0:25;
        end;
then     less_dom(max-(f), r) = {} by SUBSET_1:4;
        hence thesis by PROB_1:4;
      end;
    end;
    hence thesis;
  end;
  hence thesis;
end;
