reserve T, T1, T2 for TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  A1 for Subset of T1,
  A2 for Subset of T2,
  TM, TM1, TM2 for metrizable TopSpace,
  Am, Bm for Subset of TM,
  Fm, Gm for Subset-Family of TM,
  C for Cardinal,
  iC for infinite Cardinal;

theorem
  for M be Subset of TM, A1,A2 be closed Subset of TM, V1,V2 be open
Subset of TM st A1 c=V1 & A2 c=V2 & Cl V1 misses Cl V2 for mV1,mV2,mL be Subset
  of TM|M st mV1 = M/\Cl V1 & mV2 = M/\Cl V2 & mL separates mV1,mV2 ex L be
  Subset of TM st L separates A1,A2 & M/\L c= mL
proof
  let M be Subset of TM,A1,A2 be closed Subset of TM,V1,V2 be open Subset of
  TM such that
A1: A1 c=V1 and
A2: A2 c=V2 and
A3: Cl V1 misses Cl V2;
  set TMM=TM|M;
  let mV1,mV2,mL be Subset of TMM such that
A4: mV1=M/\Cl V1 and
A5: mV2=M/\Cl V2 and
A6: mL separates mV1,mV2;
A7: V2/\M c=mV2 by A5,PRE_TOPC:18,XBOOLE_1:26;
  consider U9,W9 be open Subset of TMM such that
A8: mV1 c=U9 and
A9: mV2 c=W9 and
A10: U9 misses W9 and
A11: mL=(U9\/W9)` by A6;
A12: [#]TMM=M by PRE_TOPC:def 5;
  then reconsider u=U9,w=W9 as Subset of TM by XBOOLE_1:1;
  set u1=u\/A1,w1=w\/A2;
A13: mV2/\u c=U9/\W9 by A9,XBOOLE_1:26;
  U9,W9 are_separated by A10,TSEP_1:37;
  then
A14: u,w are_separated by CONNSP_1:5;
  V2/\u = V2/\(M/\u) by A12,XBOOLE_1:28
    .= V2/\M/\u by XBOOLE_1:16;
  then V2/\u c=mV2/\u by A7,XBOOLE_1:26;
  then V2/\u c=U9/\W9 by A13;
  then V2/\u c={} by A10;
  then V2/\u={};
  then V2 misses u;
  then
A15: V2 misses Cl u by TSEP_1:36;
A16: Cl u1 misses w1
  proof
    assume Cl u1 meets w1;
    then consider x be object such that
A17: x in Cl u1 & x in w1 by XBOOLE_0:3;
A18: Cl u1=(Cl u)\/Cl A1 by PRE_TOPC:20;
    per cases by A17,A18,XBOOLE_0:def 3;
    suppose
      x in Cl u & x in w;
      then w meets Cl u by XBOOLE_0:3;
      hence contradiction by A14,CONNSP_1:def 1;
    end;
    suppose
      x in Cl u & x in A2;
      hence contradiction by A2,A15,XBOOLE_0:3;
    end;
    suppose
A19:  x in Cl A1 & x in w;
      Cl A1 c=Cl V1 by A1,PRE_TOPC:19;
      then x in mV1 by A4,A12,A19,XBOOLE_0:def 4;
      hence contradiction by A8,A10,A19,XBOOLE_0:3;
    end;
    suppose
A20:  x in Cl A1 & x in A2;
A21:  Cl A1 c=Cl V1 & V2 c=Cl V2 by A1,PRE_TOPC:18,19;
      x in V2 by A2,A20;
      hence thesis by A3,A20,A21,XBOOLE_0:3;
    end;
  end;
A22: V1/\M c=mV1 by A4,PRE_TOPC:18,XBOOLE_1:26;
A23: mV1/\w c=U9/\W9 by A8,XBOOLE_1:26;
  V1/\w = V1/\(M/\w) by A12,XBOOLE_1:28
    .= V1/\M/\w by XBOOLE_1:16;
  then V1/\w c=mV1/\w by A22,XBOOLE_1:26;
  then V1/\w c=U9/\W9 by A23;
  then V1/\w c={} by A10;
  then V1/\w={};
  then V1 misses w;
  then
A24: V1 misses Cl w by TSEP_1:36;
  Cl w1 misses u1
  proof
    assume Cl w1 meets u1;
    then consider x be object such that
A25: x in Cl w1 & x in u1 by XBOOLE_0:3;
A26: Cl w1=(Cl w)\/Cl A2 by PRE_TOPC:20;
    per cases by A25,A26,XBOOLE_0:def 3;
    suppose
      x in Cl w & x in u;
      then Cl w meets u by XBOOLE_0:3;
      hence contradiction by A14,CONNSP_1:def 1;
    end;
    suppose
      x in Cl w & x in A1;
      hence contradiction by A1,A24,XBOOLE_0:3;
    end;
    suppose
A27:  x in Cl A2 & x in u;
      Cl A2 c=Cl V2 by A2,PRE_TOPC:19;
      then x in mV2 by A5,A12,A27,XBOOLE_0:def 4;
      hence contradiction by A9,A10,A27,XBOOLE_0:3;
    end;
    suppose
A28:  x in Cl A2 & x in A1;
A29:  Cl A2 c=Cl V2 & V1 c=Cl V1 by A2,PRE_TOPC:18,19;
      x in V1 by A1,A28;
      hence thesis by A3,A28,A29,XBOOLE_0:3;
    end;
  end;
  then u1,w1 are_separated by A16,CONNSP_1:def 1;
  then consider U1,W1 be open Subset of TM such that
A30: u1 c=U1 and
A31: w1 c=W1 and
A32: U1 misses W1 by Lm13;
  take L=(U1\/W1)`;
  A2 c=w1 by XBOOLE_1:7;
  then
A33: A2 c=W1 by A31;
  w c=w1 by XBOOLE_1:7;
  then
A34: w c=W1 by A31;
  u c=u1 by XBOOLE_1:7;
  then u c=U1 by A30;
  then
A35: u\/w c=U1\/W1 by A34,XBOOLE_1:13;
  A1 c=u1 by XBOOLE_1:7;
  then A1 c=U1 by A30;
  hence L separates A1,A2 by A32,A33;
A36: ([#]TMM)\(U9\/W9) = mL by A11;
  M/\L = (M/\[#]TM)\(U1\/W1) by XBOOLE_1:49
    .= M\(U1\/W1) by XBOOLE_1:28;
  then M/\L c=M\(U9\/W9) by A35,XBOOLE_1:34;
  hence thesis by A36,PRE_TOPC:def 5;
end;
