reserve k,n,n1,m,m1,m0,h,i,j for Nat,
  a,x,y,X,X1,X2,X3,X4,Y for set;
reserve L,L1,L2 for FinSequence;
reserve F,F1,G,G1,H for LTL-formula;
reserve W,W1,W2 for Subset of Subformulae H;
reserve v for LTL-formula;
reserve N,N1,N2,N10,N20,M for strict LTLnode over v;
reserve w for Element of Inf_seq(AtomicFamily);
reserve R1,R2 for Real_Sequence;

theorem Th26:
  L is_Finseq_for v & m<= len(L) & L1 = L|Seg m implies L1 is_Finseq_for v
proof
  assume that
A1: L is_Finseq_for v and
A2: m<= len(L) and
A3: L1 = L|Seg m;
  reconsider L1 as FinSequence;
A4: len(L1) = m by A2,A3,FINSEQ_1:17;
A5: dom L1 = Seg m by A2,A3,FINSEQ_1:17;
  for k st 1 <= k & k < len(L1) holds ex N1,N2 st N1 = L1.k & N2=L1.(k+1)
  & N2 is_succ_of N1
  proof
    let k such that
A6: 1 <= k and
A7: k < len(L1);
    k in dom L1 by A4,A5,A6,A7,FINSEQ_1:1;
    then
A8: L1.k=L.k by A3,FUNCT_1:47;
    1<= k+1 & k+1<=m by A4,A6,A7,NAT_1:13;
    then k+1 in dom L1 by A5,FINSEQ_1:1;
    then
A9: L1.(k+1)=L.(k+1) by A3,FUNCT_1:47;
    k < len(L) by A2,A4,A7,XXREAL_0:2;
    hence thesis by A1,A6,A8,A9;
  end;
  hence thesis;
end;
