reserve A,B,a,b,c,d,e,f,g,h for set;

theorem Th26:
  for R being non empty transitive reflexive RelStr, x,y being
  Element of R holds the InternalRel of R reduces x,y implies [x,y] in the
  InternalRel of R
proof
  let R be non empty transitive reflexive RelStr;
  let x,y be Element of R;
  set cR = the carrier of R, IR = the InternalRel of R;
  assume IR reduces x,y;
  then consider p being RedSequence of IR such that
A1: p.1 = x and
A2: p.len p = y by REWRITE1:def 3;
  reconsider p as FinSequence;
  defpred P[Nat] means $1 in dom p implies [p.1,p.$1] in IR;
A3: IR is_transitive_in cR by ORDERS_2:def 3;
A4: for k be non zero Nat st P[k] holds P[k+1]
  proof
    let k be non zero Nat such that
A5: P[k];
    assume
A6: k+1 in dom p;
    then k <= k+1 & k+1 <= len p by FINSEQ_3:25,NAT_1:11;
    then
A7: 0 + 1 <= k & k <= len p by NAT_1:13;
    then
A8: p.1 in cR by A5,FINSEQ_3:25,ZFMISC_1:87;
    k in dom p by A7,FINSEQ_3:25;
    then
A9: [p.k,p.(k+1)] in IR by A6,REWRITE1:def 2;
    then p.k in cR & p.(k+1) in cR by ZFMISC_1:87;
    hence thesis by A3,A5,A7,A9,A8,FINSEQ_3:25;
  end;
  IR is_reflexive_in cR by ORDERS_2:def 2;
  then
A10: P[1] by A1;
A11: for k be non zero Nat holds P[k] from NAT_1:sch 10(A10,A4);
A12: len p > 0 by REWRITE1:def 2;
  then 0 + 1 <= len p by NAT_1:13;
  then len p in dom p by FINSEQ_3:25;
  hence thesis by A1,A2,A12,A11;
end;
