reserve F for Field;
reserve a,b,c,d,p,q,r for Element of MPS(F);
reserve e,f,g,h,i,j,k,l,m,n,o,w for Element of [:the carrier of F,the carrier
  of F,the carrier of F:];
reserve K,L,M,N,R,S for Element of F;
reserve FdSp for FanodesSp;
reserve a,b,c,d,p,q,r,s,o,x,y for Element of FdSp;

theorem Th26:
  parallelogram a,b,c,d implies a<>b & b<>c & c <>a & a<>d & b<>d & c <>d
proof
  assume
A1: parallelogram a,b,c,d;
A2: now
    assume a=d;
    then a,b '||' c,a by A1;
    then
A3: a,b '||' a,c by PARSP_1:23;
    not a,b,c are_collinear by A1;
    hence contradiction by A3;
  end;
A4: now
    assume c =d;
    then a,c '||' b,c by A1;
    then c,a '||' c,b by PARSP_1:23;
    then
A5: a,b '||' a,c by PARSP_1:24;
    not a,b,c are_collinear by A1;
    hence contradiction by A5;
  end;
A6: now
    assume b=d;
    then a,b '||' c,b by A1;
    then b,a '||' b,c by PARSP_1:23;
    then
A7: a,b '||' a,c by PARSP_1:24;
    not a,b,c are_collinear by A1;
    hence contradiction by A7;
  end;
  not a,b,c are_collinear by A1;
  hence thesis by A2,A6,A4,Th12;
end;
