
theorem Th26:
  for I being finite non empty set for A being PLS-yielding
ManySortedSet of I st for i being Element of I holds A.i is strongly_connected
for f being Collineation of Segre_Product A for B1,B2 being Segre-Coset of A st
  B1 misses B2 & B1 '||' B2 for b1,b2 being Segre-like non trivial-yielding
  ManySortedSubset of Carrier A st product b1 = B1 & product b2 = B2 holds
  canonical_embedding(f,b1) = canonical_embedding(f,b2)
proof
  let I be finite non empty set;
  let A be PLS-yielding ManySortedSet of I such that
A1: for i being Element of I holds A.i is strongly_connected;
  let f be Collineation of Segre_Product A;
  let B1,B2 be Segre-Coset of A such that
A2: B1 misses B2 and
A3: B1 '||' B2;
  let b1,b2 be Segre-like non trivial-yielding ManySortedSubset of Carrier A
  such that
A4: product b1 = B1 and
A5: product b2 = B2;
A6: indx(b1)=indx(b2) by A2,A3,A4,A5,Th21;
  reconsider B3=f.:B1,B4=f.:B2 as Segre-Coset of A by A1,PENCIL_2:24;
A7: f is bijective by PENCIL_2:def 4;
  then
A8: B3 misses B4 by A2,FUNCT_1:66;
  set i = indx(b1);
  consider r being Element of I such that
A9: r<>indx(b1) and
A10: for i being Element of I st i<>r holds b1.i=b2.i and
A11: for c1,c2 being Point of A.r st b1.r={c1} & b2.r={c2} holds c1,c2
  are_collinear by A2,A3,A4,A5,Th21;
  consider b4 being Segre-like non trivial-yielding ManySortedSubset of
  Carrier A such that
A12: product b4 = B4 and
A13: b4.indx(b4) = [#](A.indx(b4)) by PENCIL_2:def 2;
  consider b3 being Segre-like non trivial-yielding ManySortedSubset of
  Carrier A such that
A14: product b3 = B3 and
A15: b3.indx(b3) = [#](A.indx(b3)) by PENCIL_2:def 2;
  B3 '||' B4 by A3,Th20;
  then
A16: indx(b3)=indx(b4) by A8,A14,A12,Th21;
  set j = indx(b3);
A17: dom f = the carrier of Segre_Product A by FUNCT_2:def 1;
A18: dom b1 = I by PARTFUN1:def 2;
A19: now
    b2.r is trivial by A6,A9,PENCIL_1:def 21;
    then consider c2 being object such that
A20: b2.r = {c2} by ZFMISC_1:131;
    b2 c= Carrier A by PBOOLE:def 18;
    then b2.r c= (Carrier A).r;
    then
A21: {c2} c= [#](A.r) by A20,Th7;
    let o be object;
    consider p0 being object such that
A22: p0 in product b1 by XBOOLE_0:def 1;
    assume o in the carrier of A.i;
    then reconsider u=o as Point of A.i;
    reconsider p1=p0 as Point of Segre_Product A by A4,A22;
    reconsider p=p1 as ManySortedSet of I by PENCIL_1:14;
    set q=p+*(i,u);
    reconsider q1=q as Point of Segre_Product A by PENCIL_1:25;
    b1.r is trivial by A9,PENCIL_1:def 21;
    then consider c1 being object such that
A23: b1.r = {c1} by ZFMISC_1:131;
    b1 c= Carrier A by PBOOLE:def 18;
    then b1.r c= (Carrier A).r;
    then {c1} c= [#](A.r) by A23,Th7;
    then reconsider c1 as Point of A.r by ZFMISC_1:31;
    reconsider c2 as Point of A.r by A21,ZFMISC_1:31;
    set t=q+*(r,c2);
    q is Point of Segre_Product A by PENCIL_1:25;
    then reconsider t1=t as Point of Segre_Product A by PENCIL_1:25;
    per cases;
    suppose
A24:  c1<>c2;
      q.r = p.r by A9,FUNCT_7:32;
      then q.r in b1.r by A18,A22,CARD_3:9;
      then
A25:  q.r = c1 by A23,TARSKI:def 1;
      dom q = I by PARTFUN1:def 2;
      then
A26:  t.r=c2 by FUNCT_7:31;
      now
        let q3,t3 be ManySortedSet of I such that
A27:    q3=q1 & t3=t1;
        take r;
        thus for a,b being Point of A.r st a=q3.r & b=t3.r holds a<>b & a,b
        are_collinear by A11,A23,A20,A24,A25,A26,A27;
        let j be Element of I;
        assume j<>r;
        hence q3.j = t3.j by A27,FUNCT_7:32;
      end;
      then q1,t1 are_collinear by A24,A25,A26,Th17;
      then
A28:  f.q1,f.t1 are_collinear by Th1;
      reconsider fq=f.q1,ft=f.t1 as ManySortedSet of I by PENCIL_1:14;
A29:  dom b1 = I by PARTFUN1:def 2;
A30:  dom p = I by PARTFUN1:def 2;
A31:  now
        let a be object;
        assume
A32:    a in I;
        per cases;
        suppose
          a=i;
          then q.a = u & b1.a = [#](A.i) by A4,A30,Th10,FUNCT_7:31;
          hence q.a in b1.a;
        end;
        suppose
          a<>i;
          then q.a = p.a by FUNCT_7:32;
          hence q.a in b1.a by A22,A29,A32,CARD_3:9;
        end;
      end;
A33:  dom q = I by PARTFUN1:def 2;
      then
A34:  q in product b1 by A29,A31,CARD_3:9;
A35:  now
        let a be object;
        assume
A36:    a in I;
        per cases;
        suppose
A37:      a=r;
          then t.a = c2 by A33,FUNCT_7:31;
          hence t.a in b2.a by A20,A37,TARSKI:def 1;
        end;
        suppose
A38:      a<>r;
          then t.a = q.a by FUNCT_7:32;
          then t.a in b1.a by A31,A36;
          hence t.a in b2.a by A10,A36,A38;
        end;
      end;
      dom t = I & dom b2 = I by PARTFUN1:def 2;
      then
A39:  t in product b2 by A35,CARD_3:9;
      then
A40:  canonical_embedding(f,b2).(t.i)=ft.(permutation_of_indices(f) .i)
      by A1,A5,A6,Def4;
A41:  f.q1 <> f.t1 by A17,A7,A24,A25,A26,FUNCT_1:def 4;
A42:  now
        consider l being Element of I such that
        for a,b being Point of A.l st a=fq.l & b=ft.l holds a<>b & a,b
        are_collinear and
A43:    for j being Element of I st j<>l holds fq.j = ft.j by A41,A28,Th17;
        assume fq.j<>ft.j;
        then
A44:    j=l by A43;
A45:    dom b4=I by PARTFUN1:def 2;
A46:    fq in B3 by A17,A4,A34,FUNCT_1:def 6;
A47:    dom b3 = I by PARTFUN1:def 2;
A48:    now
          let o be object;
          assume o in I;
          then reconsider o1=o as Element of I;
          per cases;
          suppose
            o1=j;
            hence fq.o in b4.o by A14,A15,A13,A16,A46,A47,CARD_3:9;
          end;
          suppose
            o1<>j;
            then
A49:        fq.o1 = ft.o1 by A43,A44;
            ft in product b4 by A17,A5,A12,A39,FUNCT_1:def 6;
            hence fq.o in b4.o by A45,A49,CARD_3:9;
          end;
        end;
        dom fq = I by PARTFUN1:def 2;
        then fq in product b4 by A45,A48,CARD_3:9;
        then fq in product b3 /\ product b4 by A14,A46,XBOOLE_0:def 4;
        hence contradiction by A8,A14,A12;
      end;
A50:  j=permutation_of_indices(f).i by A1,A4,A14,Def3;
      dom p = I by PARTFUN1:def 2;
      then
A51:  q.i=o by FUNCT_7:31;
      then t.i=o by A9,FUNCT_7:32;
      hence
      canonical_embedding(f,b1).o = canonical_embedding(f,b2).o by A1,A4,A50
,A34,A40,A42,A51,Def4;
    end;
    suppose
A52:  c1=c2;
A53:  now
        let o be object;
        assume o in I;
        then reconsider o1=o as Element of I;
        per cases;
        suppose
          r=o1;
          hence b1.o=b2.o by A23,A20,A52;
        end;
        suppose
          r<>o1;
          hence b1.o=b2.o by A10;
        end;
      end;
      dom b1 = I & dom b2 = I by PARTFUN1:def 2;
      hence canonical_embedding(f,b1).o = canonical_embedding(f,b2).o by A53,
FUNCT_1:2;
    end;
  end;
  dom canonical_embedding(f,b1) = the carrier of A.i & dom
  canonical_embedding (f,b2) = the carrier of A.i by A6,FUNCT_2:def 1;
  hence thesis by A19;
end;
