reserve A,B,C for Ordinal,
        o for object,
        x,y,z,t,r,l for Surreal,
        X,Y for set;

theorem Th26:
  for S be c=-monotone Function-yielding Sequence st
    for B be Ordinal st B in dom S
      ex SB be ManySortedSet of Triangle B st S.B = SB &
        for x be object st x in Triangle B holds
          SB.x = [union rng(S|B).:([:L_L_x,{R_x}:]\/[:{L_x},L_R_x:]),
                  union rng(S|B).:([:R_L_x,{R_x}:]\/[:{L_x},R_R_x:])]
     holds
  for A be Ordinal st A in dom S holds No_sum_op A = S.A
proof
  deffunc D(Ordinal) = Triangle $1;
  deffunc H(object,c=-monotone Function-yielding Sequence) =
  [union rng $2.:([:L_L_$1,{R_$1}:]\/[:{L_$1},L_R_$1:] ),
  union rng $2.:([:R_L_$1,{R_$1}:]\/[:{L_$1},R_R_$1:])];
  let S be c=-monotone Function-yielding Sequence such that
      A1: for B be Ordinal st B in dom S
         ex SB be ManySortedSet of D(B) st S.B = SB &
           for x be object st x in D(B) holds
             SB.x = H(x,S|B);
  let A be Ordinal such that A2: A in dom S;
  consider S1 be c=-monotone Function-yielding Sequence such that
  A3:dom S1 = succ A & No_sum_op A = S1.A and
  A4:for B be Ordinal st B in succ A
    ex SB be ManySortedSet of D(B) st S1.B = SB &
      for x be object st x in D(B) holds SB.x = H(x,S1|B) by Def6;
  A5:succ A c= dom S by A2,ORDINAL1:21;
  A6: for B be Ordinal st B in succ A
    ex SB be ManySortedSet of D(B) st S.B = SB &
      for x be object st x in D(B) holds SB.x = H(x,S|B) by A1,A5;
  A7: succ A c= dom S & succ A c= dom S1 by A2,ORDINAL1:21,A3;
  A8: S|succ A = S1|succ A from MonoFvSUniq(A7,A6,A4);
  A in succ A by ORDINAL1:8;
  hence thesis by A3,A8,FUNCT_1:49;
end;
