reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem
  for S1 being sequence of T holds S1 is Cauchy implies rng S1 is bounded
proof
  let S1 be sequence of T;
  set A = rng S1;
  assume S1 is Cauchy;
  then consider p such that
A1: for n,m st p<=n & p<=m holds dist(S1.n,S1.m)<1;
  defpred X[set] means ex n st p<=n & $1 = S1.n;
  reconsider B = {t1 where t1 is Point of T : X[t1] } as Subset of T from
  DOMAIN_1:sch 7;
  defpred X[set] means ex n st n<=p & $1 = S1.n;
  reconsider C = {t1 where t1 is Point of T : X[t1] } as Subset of T from
  DOMAIN_1:sch 7;
  reconsider B, C as Subset of T;
A2: C is finite
  proof
    set K = Seg p;
    set J = {0} \/ K;
    now
      let x be object;
      thus x in C implies x in S1.:J
      proof
        assume x in C;
        then consider t1 such that
A3:     x = t1 and
A4:     ex n st n<=p & t1 = S1.n;
        consider n such that
A5:     n<=p and
A6:     t1 = S1.n by A4;
        n in NAT by ORDINAL1:def 12;
        then
A7:     n in dom S1 by FUNCT_2:def 1;
        now
          per cases by NAT_1:6;
          suppose
            n=0;
            then n in {0} by TARSKI:def 1;
            then n in J by XBOOLE_0:def 3;
            hence thesis by A3,A6,A7,FUNCT_1:def 6;
          end;
          suppose
            ex m be Nat st n=m+1;
            then 1<=n by NAT_1:11;
            then n in { k where k is Nat: 1<=k & k<=p } by A5;
            then n in K by FINSEQ_1:def 1;
            then n in J by XBOOLE_0:def 3;
            hence thesis by A3,A6,A7,FUNCT_1:def 6;
          end;
        end;
        hence thesis;
      end;
      assume x in S1.:J;
      then consider y being object such that
A8:   y in dom S1 and
A9:   y in J and
A10:  x=S1.y by FUNCT_1:def 6;
      reconsider y as Nat by A8;
      now
        per cases by A9,XBOOLE_0:def 3;
        suppose
A11:      y in {0};
          S1.y is Element of T;
          then reconsider x9=x as Element of T by A10;
          y=0 by A11,TARSKI:def 1;
          then ex n st n<=p & x9=S1.n by A10;
          hence x in C;
        end;
        suppose
A12:      y in K;
          S1.y is Element of T;
          then reconsider x9=x as Element of T by A10;
          y in {k where k is Nat : 1<=k & k<=p } by A12,FINSEQ_1:def 1;
          then ex k being Nat st y = k & 1<=k & k<=p;
          then ex n st n<=p & x9=S1.n by A10;
          hence x in C;
        end;
      end;
      hence x in C;
    end;
    hence thesis by TARSKI:2;
  end;
A13: A = B \/ C
  proof
    thus A c= B \/ C
    proof
      let x be object;
      assume x in A;
      then consider y being object such that
A14:  y in dom S1 and
A15:  x = S1.y by FUNCT_1:def 3;
      reconsider y as Nat by A14;
      S1.y is Element of T;
      then reconsider x9=x as Element of T by A15;
      per cases;
      suppose
        y<=p;
        then ex n st n<=p & x9= S1.n by A15;
        then x in C;
        hence thesis by XBOOLE_0:def 3;
      end;
      suppose
        p<=y;
        then ex n st p<=n & x9= S1.n by A15;
        then x in B;
        hence thesis by XBOOLE_0:def 3;
      end;
    end;
    let x be object;
    assume
A16: x in B \/ C;
    per cases by A16,XBOOLE_0:def 3;
    suppose
      x in B;
      then consider t1 such that
A17:  x = t1 and
A18:  ex n st p<=n & t1 = S1.n;
      consider n such that
      p<=n and
A19:  t1 = S1.n by A18;
      n in NAT by ORDINAL1:def 12;
      then n in dom S1 by FUNCT_2:def 1;
      hence thesis by A17,A19,FUNCT_1:def 3;
    end;
    suppose
      x in C;
      then consider t1 such that
A20:  x = t1 and
A21:  ex n st n<=p & t1 = S1.n;
      consider n such that
      n<=p and
A22:  t1 = S1.n by A21;
      n in NAT by ORDINAL1:def 12;
      then n in dom S1 by FUNCT_2:def 1;
      hence thesis by A20,A22,FUNCT_1:def 3;
    end;
  end;
  B is bounded
  proof
    set x=S1.p;
    ex r,t1 st 0<r & t1 in B & for z being Point of T st z in B holds
    dist(t1,z)<=r
    proof
      take 1,x;
      thus 0<1;
      thus x in B;
      let z be Point of T;
      assume z in B;
      then ex t1 st z = t1 & ex n st p<=n & t1 = S1.n;
      hence thesis by A1;
    end;
    hence thesis by Th10;
  end;
  hence thesis by A2,A13,Th13;
end;
