reserve a,b,c for set;
reserve r for Real,
  X for set,
  n for Element of NAT;

theorem Th26:
  for X being infinite Subset of NAT, i being Nat holds
  (Partial_Sums (X-powers (1/2))).i < Sum (X-powers (1/2))
proof
  set r = 1/2;
  let X be infinite Subset of NAT;
  let i be Nat;
  defpred P[Nat] means (Partial_Sums (X-powers r)).i <= (
  Partial_Sums (X-powers r)).(i+$1);
  not X c= i+1;
  then consider a being object such that
A1: a in X and
A2: not a in i+1;
  reconsider a, j = i as Element of NAT by A1,ORDINAL1:def 12;
A3: (X-powers r).a = r|^a by A1,Def5;
A4: now
    let n be Nat;
    n in X & (X-powers r).n = r|^n or not n in X & (X-powers r).n = 0 by Def5;
    hence 0 <= (X-powers r).n by PREPOWER:6;
  end;
A5: now
    let k be Nat such that
A6: P[k];
    i+(k+1) = i+k+1;
    then
A7: (Partial_Sums (X-powers r)).(j+(k+1)) = (Partial_Sums (X-powers r)).(
    j+k) + (X-powers r).(j+(k+1)) by SERIES_1:def 1;
    (X-powers r).(j+(k+1)) >= 0 by A4;
    then
    (Partial_Sums (X-powers r)).(j+k) + 0 <= (Partial_Sums (X-powers r)).
    (j+(k+1)) by A7,XREAL_1:6;
    hence P[k+1] by A6,XXREAL_0:2;
  end;
  Segm(j+1) c= Segm a by A2,ORDINAL1:16;
  then j+1 <= a by NAT_1:39;
  then consider k being Nat such that
A8: a = (j+1)+k by NAT_1:10;
  reconsider k as Element of NAT by ORDINAL1:def 12;
  r|^a > 0 by PREPOWER:6;
  then
A9: (Partial_Sums (X-powers r)).i + r|^a > (Partial_Sums (X-powers r)).i +
  0 by XREAL_1:6;
A10: P[ 0 ];
  for k being Nat holds P[k] from NAT_1:sch 2(A10,A5);
  then
A11: (Partial_Sums (X-powers r)).i <= (Partial_Sums (X-powers r)).(i+k);
  j+(k+1) = j+k+1;
  then
  (Partial_Sums (X-powers r)).a = (Partial_Sums (X-powers r)).(j+k) + r|^
  a by A3,A8,SERIES_1:def 1;
  then (Partial_Sums (X-powers r)).i + r|^a <= (Partial_Sums (X-powers r)).a
  by A11,XREAL_1:6;
  then
A12: (Partial_Sums (X-powers r)).i < (Partial_Sums (X-powers r)).a by A9,
XXREAL_0:2;
  (Partial_Sums (X-powers (1/2))).a <= Sum (X-powers (1/2)) by Th21,A4,
IRRAT_1:29;
  hence thesis by A12,XXREAL_0:2;
end;
